Computations of the alternative expansion for self-avoiding walk

The expansion of Chapter 6 with the Analysis of Section 3.3

Robert Fitzner

This file performs the numerical part of the analysis of the lace expansion for the nearest-neighbor self-avoiding walk explained in Chapter 6 of the thesis of the author. All references in this version of the notebook will be to the PhD thesis. The first three sections in the notebook are the same as in the document for the SAW-NoBLE computations.

As input the dimension d and the constance (Subscript[Γ, 1]),(Subscript[Γ, 2]),(Subscript[Γ, 3]),(Subscript[c, 2]),(Subscript[c, 4]) are expected. After choosing these quantities we select the menu item Evaluate-> Evaluate Notebook. In a table at the end of this document we will then be shown whether the bootstrap and thereby the analysis is succesful.

We first compute bounds on the simple random walk two-point function (Section 5.2). Then we compute bound on the two-point function and repulsive diagrams (Section 5.1.2). We use these bounds on diagrams to compute the bound on the coefficients stated and proven in Section 6.4-6.5 and compute the bounds used for the Analysis in Section 3.3 and 6.6.

02.03.2013

Input

In which dimension should we perform the computation

d=7;

For the bootstrap we assume that (Subscript[f, i])(z)≤ (Subscript[Γ, i]) with (Subscript[Γ, i]) gives as follows

Gamma1=1.021;Gamma2=1.032;Gamma3=1.1;

For the bootstrap function (Subscript[f, 3])we define constants (Subscript[c, 2]) and (Subscript[c, 4]).

c2=0.5;c4=4.13;

As the nominator (Subscript[Φ, z])of the (Subscript[G, z]) in line (7.6.1) is trivial (Subscript[c, 1])and (Subscript[c, 3])are not need. (see the analysis in Section 4.3.5)

(*d=7;Gamma1=1.021;Gamma2=1.032;Gamma3=1.1;c2=0.5;c4=4.13;*)

Simple Random Walk integral

Overview

We compute the two-point function of the simple random walk,

(Subscript[I, n,m])(x)=(∫_([ -ℼ,ℼ]))(e^(ik x))((((OverHat[D])^m) (k))/(((1-(OverHat[D])(k)))^n))(((d^d)k)/(((2π))^d))

see Section 5.2, using that

(Subscript[I, n,m])(x)=(Subscript[I, n,(m-1)])(x)-(Subscript[I, (n-1),(m-1)])(x)
(Subscript[I, n,0])(x)=(1/((n-1)!))(∫_0^∞)(t^(n-1))(∏_(i=1)^d)(∫_(-π)^π)(e^(-t/d(1-cos((Subscript[k, i]))))(e^((Subscript[ιk, i])(Subscript[x, i])))(dk/(2π)) =(1/((n-1)!))(∫_0^∞)(t^(n-1))(∏_(i=1)^d)F(t,d,(Abs[(Subscript[x, i])]))

where F(t,d,n) is the modified Besselfunction. We implement the Besselfunciton and a function to compute (Subscript[I, n,0])(0).

F[t_,d_,N_]:= (E^(-(t/d))) BesselI[N,(t/d)];
NInt[n_,d_,T_]:=1/((n-1)!)*NIntegrate[t^(n-1)*(F[t,d,0])^d,{t,0,T}]

Computation

Then we define the number of n-step SRW loop as given in Section (5.2.6)-(5.2.10)

s2=N[2d];
s4=N[(d*((4!)/(2 2))+((d(d-1))/2)*4!)];
s6=N[ (d*((6!)/(3!3!))+d*(d-1)*((6!)/(2 2))+((d(d-1)(d-2))/(3!))*6!)];
s8=N[(d*((8!)/(4!4!))+d*(d-1)*(((8!)/(3!3!))+((8!)/(2^5)))+((d(d-1)(d-2))/2)*((8!)/(2 2))+((d(d-1)(d-2)(d-3))/(4!))*8!)];

We compute the number (Subscript[I, n,m]) for n=0,1,2 and m=1,...,10 and save them in an two-dimensional array:

TableTwoPointValues = {{ n m,0, 1, 2}, {0,1, NInt[1,d,∞], NInt[2,d,∞]}, {1,0,0,0}, {2,(s2/(((2d))^2)), 0,0}, {3,0, 0,0}, {4,(s4/(((2d))^4)), 0,0},{5, 0,0,0},{6,(s6/(((2d))^6)),0,0},{7, 0,0,0},{8, (s8/(((2d))^8)),0,0},{9, 0,0,0},{10, -1,0,0}}; 
For[i=3,i<13,i++,
For[j=3,j<5,j++,
TableTwoPointValues[[i,j]]=TableTwoPointValues[[i-1,j]]-TableTwoPointValues[[i-1,j-1]];]
]
Clear[i,j]

For latter reference we define the constants:

I10=TableTwoPointValues[[2,3]];
I11=TableTwoPointValues[[3,3]];
I12=TableTwoPointValues[[4,3]];
I14=TableTwoPointValues[[6,3]];
I16=TableTwoPointValues[[8,3]];
I18=TableTwoPointValues[[10,3]];
I110=TableTwoPointValues[[12,3]];
I20=TableTwoPointValues[[2,4]];
I21=TableTwoPointValues[[3,4]];
I22=TableTwoPointValues[[4,4]];
I24=TableTwoPointValues[[6,4]];
I26=TableTwoPointValues[[8,4]];
I28=TableTwoPointValues[[10,4]];
I210=TableTwoPointValues[[12,4]];

Print out of all computed values of (Subscript[I, n,m])

Labeled[Grid[TableTwoPointValues, Alignment -> {{Left, Center}, Baseline, {{2, 12}, {2, 3}} -> {"."}}, Frame -> True, Dividers -> {{2 -> True, -1 -> True}, {2 -> True}}, Spacings -> {1.5, {1.5, 1, {0.5}}}, ItemStyle -> {1 -> Bold, 1 -> Bold}, Background -> {Automatic, Automatic, {{2, 12}, {2, 4}} -> GrayLevel[0.9]}], Style["Value of the SRW two-point function in dimension "Text[d] , Bold], Top] // Text

Bound on the two-point function and on repulsive diagrams

Definition of Constants

We consider two setting s: we use s=i for bound on z=(Subscript[z, I]) and s=o for bound on zϵ ((Subscript[z, I]),(Subscript[z, c])). In section 5.1 we argued that the bounds have a similar for. As given in (5.1.13) and (5.1.14) we define

z[i]=(1/(2d-1));
z[o]=(Gamma1/(2d-1));
VarGamma2[i]=((2(d-1))/(2d-1));(* (Subscript[G, 1/(2d-1)])(x) >=(Subscript[B, 1/(2d-1)])(x) = ((2d-2)/(2d-1)) (Subscript[C, 1/2d])(x)*)
VarGamma2[o]=((2(d-1))/(2d-1))Gamma2;

Further, we define the constants given in Section 5.1.3.

c2ik=2; (*(Subscript[c, 2])((Subscript[e, 1])+(Subscript[e, 2]))*)
c4ik=4 +6(2d-4);(*(Subscript[c, 4])((Subscript[e, 1])+(Subscript[e, 2]))*)
c6ik=16+84(2d-4)+36(2d-4)(2d-6);(*(Subscript[c, 4])((Subscript[e, 1])+(Subscript[e, 2]))*)

c3i=(2d-2);(*(Subscript[c, 3])((Subscript[e, 1]))*)
c5i=(3(2d-2 )+4(2d-2)(2d-4) );(*(Subscript[c, 5])((Subscript[e, 1]))*)
c7i=(14(2d-2 )+62(2d-2)(2d-4)+27(2d-2)(2d-4)(2d-6) );(*(Subscript[c, 7])((Subscript[e, 1]))*)

Bounds on two-point function

We compute bounds as explained in Section 5.1.2.We begin by computing (Subscript[G, n,z])((Subscript[e, 1])) as in (5.1.22)-(5.1.24)

Do[
Bound[G7i,s]=c7i ((z[s])^7)+(2d*z[s])^9*VarGamma2[s]*I110;(* (Subscript[G, 7,z])((Subscript[e, 1]))*)
Bound[G5i,s]=c5i ((z[s])^5)+Bound[G7i,s];(* (Subscript[G, 5,z])((Subscript[e, 1]))*)
Bound[G3i,s]=c3i ((z[s])^3)+Bound[G5i,s];(* (Subscript[G, 3,z])((Subscript[e, 1]))*)
Bound[G1i,s]=z[s]+Bound[G3i,s];(* (Subscript[G, 1,z])((Subscript[e, 1]))*)
,{s,{i,o}}]

Then we compute (Subscript[G, n,z])((Subscript[e, 1])+(Subscript[e, 2])) and (Subscript[G, 4,z])(2(Subscript[e, 2])), see (5.1.25)-(5.1.26) and (5.4.1):

Do[
Bound[G8ik,s]=(d/(d-1))(2d*z[s])^8VarGamma2[s]I110;(*(Subscript[G, 8])((Subscript[e, 1])+(Subscript[e, 2]))*)
Bound[G6ik,s]=c6ik z[s]^6+VarGamma2[s]I18;(*(Subscript[G, 6])((Subscript[e, 1])+(Subscript[e, 2]))*)
Bound[G4ik,s]=Bound[G6ik,s]+(c4ik-2(2d-3) )((z[s])^4);(*(Subscript[G, 4]^1)((Subscript[e, 1])+(Subscript[e, 2]))*)
Bound[G2ik,s]=Bound[G4ik,s]+(c2ik-1)((z[s])^2);(*(Subscript[G, 2]^1)((Subscript[e, 1])+(Subscript[e, 2]))*)
Bound[G4ii,s]=(2d+2)((z[s])^4)+Bound[G6,s];(* Bound for (sup_x)(Subscript[G, 4]^1)(2 (Subscript[e, 1]))*)
,{s,{i,o}}]

We compute the supreme of the two-point function as given in (5.1.28)-(5.1.31):

Do[
Bound[G6,s]=Max[Bound[G7i,s],Bound[G6ik,s],(2d*z[s])^8VarGamma2[s]I18]; (* Bound for (sup_x) (Subscript[G, 6])(x)=Max[(Subscript[G, 7])(e),(Subscript[G, 6])((Subscript[e, 1])+(Subscript[e, 2])),(sup_x) (Subscript[G, 8])(x)]*)
Bound[G4,s]=Max[c4ik ((z[s])^4),c5i ((z[s])^5)]+Bound[G6,s]; (* Bound for (sup_x)(Subscript[G, 4])(x)*)
Bound[G2,s]=Max[c2ik ((z[s])^2),c3i ((z[s])^3)]+Bound[G4,s]; (* Bound for (sup_x)(Subscript[G, 2])(x)*)
Bound[G1,s]=Max[Bound[G1i,s],Bound[G2,s]];(* Bound for (sup_x)(Subscript[G, 1])(x)*)
,{s,{i,o}}]

Bounds on repulsive bubbles

As next we bound the closed diagrams, see (5.1.37). For the bounds we note that (Subscript[B, (UnderBar[1]),3])(0)= 2d z (Subscript[G, 3,z])((Subscript[e, 1])) and (Subscript[B, 1,2])(0)=(Subscript[B, (UnderBar[1]),3])(0)+(Subscript[B, 2,2])(0)

Do[
RepBubble[Step,G3,s]=2d z[s]Bound[G3i,s] ;
RepBubble[G2,G2,s]=2d c3i ((z[s])^4)+2d 3  c5i ((z[s])^6)+2d 5  c7i ((z[s])^8)+(((2d z[s]))^10)(4VarGamma2[s]I110+((VarGamma2[s])^2)I210);
RepBubble[G1,G2,s]=RepBubble[Step,G3,s]+RepBubble[G2,G2,s];
,{s,{i,o}}]

We bound the open diagram (Subscript[B, 2,0])(0) as in (5.1.38) and see that we can use the same bound for (Subscript[B, 1,1])(0) and that (Subscript[B, 0,1])(0)=(Subscript[B, (UnderBar[0]),1])(0)+(Subscript[B, 1,1])(0):

Do[
OpenRepBubble[G2,G0,s]=Max[c2ik ((z[o])^2)+3c4ik ((z[o])^4),2c3i ((z[o])^3)+4c5i ((z[o])^5)]+4(((2d z[o]))^6)VarGamma2[o]I16+(((2d z[o]))^6)((VarGamma2[o])^2)I26;
OpenRepBubble[G1,G1,s]=OpenRepBubble[G2,G0,s];
OpenRepBubble[G0,G1,s]=Bound[G1,s]+OpenRepBubble[G1,G1,s];
,{s,{i,o}}]

Bounds on weighted diagrams

We bound (sup_x)(Subscript[G, z])(x)[1-cos(k x)] as how in (5.1.19) and (5.1.20):

Bound[DeltaG,o]=(2c2+c4)I20 Gamma3 ;
Bound[DeltaG,i]=((2d-2)/(2d-1))(I20+4I20) ;

Further, we bound (Subscript[Σ, x])(((Subscript[G, 2,z])(x))^2)(Subscript[G, z])(x)[1-cos(k x)] as explained in Section 5.4.1 and given (5.4.4).  For z=(Subscript[z, I]), so s=i we use (5.1.20) to use also the bound (5.4.4) with (Subscript[c, 1])=0,(Subscript[c, 3])=0,(Subscript[c, 2])=0.5:

Bound[G2CubedAndOneWeight,o]:= (((2d z[o]))^4)((VarGamma2[o])^2)Gamma3(2c2(I12+I22)(I24-(I12^2))+2c2 I20 (I12^2));
Bound[G2CubedAndOneWeight,i]:= (((2d z[i]))^4)(((((2(d-1))/(2d-1))))^3)((I12+I22)(I24-(I12^2))+I20 (I12^2));

Bound on the coefficient (Subscript[Φ, z]^ι)

Bound for N=1

We implement the bounds given in Section 6.4.1:

Do[
Bound[Phi,1,ii,s]=((z[s])^2)Bound[G4ii,s];
Bound[Phi,1,iin,s]=0;
Bound[Phi,1,ik,s]=((z[s])^2)Bound[G2ik,s];
Bound[Phi,1,sumi,s]=z[s]Bound[G3i,s];
Bound[Phi,1,Delta,s]=0;
,{s,{i,o}}]

Bound for N=2

Then the bounds given in Section 6.4.2:

Do[
bii=((z[s])^2)Bound[G3i,s]+((z[s])^2)((Bound[G4ii,s])^2)Bound[G1i,s]+(2d-2)((z[s])^2)((Bound[G2ik,s])^2)Bound[G1i,s];
biin=2((z[s])^2)Bound[G3i,s]*Bound[G4ii,s]+(2d-2)((z[s])^2)((Bound[G2ik,s])^2)Bound[G1i,s];
bik=2((z[s])^2)Bound[G2ik,s]*Bound[G1i,s](Bound[G4ii,s]+Bound[G3i,s])+(2d-4)((z[s])^2)Bound[G1i,s]((Bound[G2ik,s])^2);
bisumi=z[s]Bound[G3i,s]Bound[G1i,s]+z[s]Bound[G4ii,s]((Bound[G1i,s])^2)+(2d-2)z[s]Bound[G2ik,s](z[s]+Bound[G1i,s])Bound[G3i,s];
Bound [Phi,2,ii,s]=bii+((z[s])^2)Bound[G1,s]((RepBubble[G2,G2,s])/(2d z[s]));
Bound [Phi,2,iin,s]=biin+((z[s])^2)Bound[G1,s]((RepBubble[G2,G2,s])/(2d z[s]));
Bound [Phi,2,ik,s]=bik+((z[s])^2)Bound[G1,s]((RepBubble[G2,G2,s])/(2d z[s]));
Bound [Phi,2,sumi,s]=bisumi+2d ((z[s])^2)Bound[G1,s]((RepBubble[G2,G2,s])/(2d z[s]));
Bound [Phi,2,Delta,s]=2d bisumi+Bound[G2CubedAndOneWeight,s];
Clear[bii,biin,bik,bisumi];
,{s,{i,o}}]

Bound for N≥3

The implementation of the bounds stated in Section 6.4.3:

Declaration of variables

We implement the vectors and matricies as given in (6.4.8)-(6.4.11):

Do[
Vector[vi,s]={((z[s])/(2d))((Bound[G3i,s])^2)+z[s]Bound[G1,s]((RepBubble[G2,G2,s])/(2d z[s])),z[s] Max[1,Bound[G1,s]](2Bound[G3i,s]+((RepBubble[G2,G2,s])/(2d z[s])))};
MatrixB[s]={{Bound[G3i,s],Max[z[s],Bound[G2,s]]},{Bound[G3i,s]+((RepBubble[G2,G2,s])/(2d z[s])),OpenRepBubble[G2,G0,s]}};
Vector[w,s]={ 2d z[s]Bound[G3i,s],RepBubble[G1,G2,s]};
,{s,{i,o}}]

To compute the sum of the bound we compute the eigensystem of B and a decomposition of wand (1,1) as explained in Section 5.3:

Do[
EigensystemB[s]=Eigensystem[MatrixB[s]];
Do[
VectorB[v,j,s]=EigensystemB[s][[2,j]]*(Inverse[Transpose[  EigensystemB[s][[2]]  ]].Vector[w,s])[[j]];
EigenValueB[j,s]=EigensystemB[s][[1,j]];
,{j,{1,2}}];
,{s,{i,o}}]

Bound on the absolute value (k=0)

Do[
Bound[Phi,OddTail,sumi,s]=Sum[((Vector[vi,s].VectorB[v,j,s])/((1-((EigenValueB[j,s])^2)))),{j,1,2}];
Bound[Phi,EvenTail,sumi,s]=Sum[((Vector[vi,s].VectorB[v,j,s]EigenValueB[j,s])/((1-((EigenValueB[j,s])^2)))),{j,1,2}];
Do[
Bound[Phi,EvenTail,t,s]=Bound[Phi,EvenTail,sumi,s]/(2d);
Bound[Phi,OddTail,t,s]=Bound[Phi,OddTail,sumi,s]/(2d);
,{t,{ii,iin,ik}}];
,{s,{i,o}}]

Bounds on Difference

Do[
Bound[Phi,OddTail,Delta,s]=Bound[DeltaG,s](Sum[(({1,1}.VectorB[v,j,s])/(1-((EigenValueB[j,s])^2))),{j,1,2}])(Sum[2*(({1,1}.VectorB[v,j,s])/(((1-((EigenValueB[j,s])^2)))^2))-(({1,1}.VectorB[v,j,s])/((1-((EigenValueB[j,s])^2)))),{j,1,2}]);
Bound[Phi,EvenTail,Delta,s]=Bound[DeltaG,s](Sum[(({1,1}.VectorB[v,j,s]EigenValueB[j,s])/(1-((EigenValueB[j,s])^2))),{j,1,2}])(Sum[(({1,1}.VectorB[v,j,s])/(((1-((EigenValueB[j,s])^2)))^2)),{j,1,2}])+Bound[DeltaG,s](Sum[(({1,1}.VectorB[v,j,s])/(1-((EigenValueB[j,s])^2))),{j,1,2}])(Sum[(({1,1}.VectorB[v,j,s]EigenValueB[j,s])/(((1-((EigenValueB[j,s])^2)))^2)),{j,1,2}])+Sum[((VectorB[v,j,s]EigenValueB[j,s])/(((1-((EigenValueB[j,s])^2)))^2))+((VectorB[v,j,s]EigenValueB[j,s])/(1-((EigenValueB[j,s])^2))),{j,1,2}].{2d z[s]Bound[G3i,s]+Bound[DeltaG,s]*(Bound[G3i,s]+((RepBubble[G2,G2,s])/(2d z[s]))),Bound[DeltaG,s]*OpenRepBubble[G0,G1,s]};
,{s,{i,o}}]

Sum over N

We combine the bound we computed in the preceding sections and compute the following bound on the absolute value of (Subscript[Φ, z])

Do[
Do[
Bound[Phi,Even,t,s]=Bound[Phi,EvenTail,t,s]+Bound[Phi,2,t,s];
Bound[Phi,Odd,t,s]=Bound[Phi,OddTail,t,s]+Bound[Phi,1,t,s];
Bound[Phi,abs,t,s]=Bound[Phi,Even,t,s]+Bound[Phi,Odd,t,s];
,{t,{ii,iin,ik,sumi}}];
Bound[Phi,abs,max,s]=Max[Bound[Phi,abs,ii,s],Bound[Phi,abs,iin,s],Bound[Phi,abs,ik,s]];
,{s,{i,o}}]

For the bound on the difference we compute

Do[
Bound[Phi,abs,Delta,s]=Sum[Bound[Phi,r,Delta,s],{r,{1,2,EvenTail,OddTail}}];
Bound[Phi,Odd,Delta,s]=Sum[Bound[Phi,r,Delta,s],{r,{1,OddTail}}];
Bound[Phi,Even,Delta,s]=Sum[Bound[Phi,r,Delta,s],{r,{2,EvenTail}}];
,{s,{i,o}}]

Bound on the coefficient (Subscript[Π, z])

Bound on (Subscript[Π, z])

We first compute the bound, as shown in Section 6.5.1:

Do[
Bound[Pi,upper,s]=- ((2d ((z[i])^2))/(1+z[i]))+((2d)/(1+z[s]))((Bound[Phi,Even,sumi,s])/(1+z[s]-Bound[Phi,Odd,sumi,s]));
Bound[Pi,lower,s]= -((2d ((z[s])^2))/(1+z[s]))-((2d)/(1+z[i]))((Bound[Phi,Odd,sumi,s])/(1+z[i]-Bound[Phi,Odd,sumi,s]));
,{s,{i,o}}]

Bound on   (∑_ikx)[1-cos(kx)](Subscript[(Π^ik), z])(x)

Now we compute bounds: a lower bound for (∑_ikx)[1-cos(kx)](Subscript[(Π^ik), z])(x) and an upper bound for (∑_ikx)[1-cos(kx)]|(Subscript[(Π^ik), z])(x)|, see Section 6.5.2 and 6.5.3. We bound these differences by expanding it into eleven terms, see (6.5.7) and (6.5.10)-(6.5.14). We first bound the four explict terms. Thereby we use the label low, to denote that this corresponds to the lower bound for (∑_ikx)[1-cos(kx)](Subscript[(Π^ik), z])(x) . Everything that we use to bound (∑_ikx)[1-cos(kx)]|(Subscript[(Π^ik), z])(x)|=(Π^AV)(0)-(Π^AV)(k) will carry the label AV.

Do[
Bound[PiPart,Main,low,s]=((2d ((z[i])^3))/(1-((z[i])^2)));(*(7.5.7)*)
Bound[PiPart,Main,AV,s]=((2d ((z[s])^3))/(1-((z[s])^2)));(*(7.5.7)*)
Bound[PiPart,1,low,s]=((2d ((z[s])^3))/((1-((z[s])^2))(1+z[s])))((Bound[Phi,Odd,sumi,s])/(1-((Bound[Phi,Odd,sumi,s])/(1+z[i]))));(*(7.5.16)*)
Bound[PiPart,1,AV,s]=((2d z[s])/((1-((z[s])^2))(1-z[s])))((Bound[Phi,abs,sumi,s])/(1-((Bound[Phi,abs,sumi,s])/(1-z[s]))));(*(7.5.16)*)
Bound[PiPart,2,low,s]=Bound[PiPart,1,low,s];(*(7.5.17)*)
Bound[PiPart,2,AV,s]=Bound[PiPart,1,AV,s];(*(7.5.17)*)

Bound[PiPart,3,low,s]=((((( z[s])/((1+z[s])))))^2)((Bound[Phi,Odd,Delta,s])/(1-((Bound[Phi,Odd,sumi,s])/(1+z[i]))));(*(7.5.18)*)
Bound[PiPart,3,AV,s]=((((( z[s])/((1-z[s])))))^2)((Bound[Phi,abs,Delta,s])/(1-((Bound[Phi,abs,sumi,s])/(1-z[s]))));(*(7.5.18)*)
,{s,{i,o}}]

The other terms are bounded using matrix norms. We by computing these norms. See (6.5.24)-(6.5.36)

Do[
Bound[EucleadOfVZero,s]=(1/(1-z[s]))(Sqrt[2d]);
Bound[EucleadOfVZeroMinusVk,s]=((z[s])/(1-((z[s])^2)))(Sqrt[4d]);
Bound[EucleadBZeroOneV,low,s]=(Sqrt[2d])(1/(1-((Bound[Phi,Odd,sumi,s])/(1+z[s]))));
Bound[EucleadBZeroOneV,AV,s]=(Sqrt[2d])(1/(1-((Bound[Phi,abs,sumi,s])/(1-z[s]))));
Bound[EucleadPhiZeroOneV,low,s]=(Sqrt[2d])Max[Bound[Phi,Even,sumi,s],Bound[Phi,Odd,sumi,s]];
Bound[EucleadPhiZeroOneV,AV,s]=(Sqrt[2d])Bound[Phi,abs,sumi,s];
Bound[OPPhik,s]=Bound[Phi,abs,sumi,s];

Bound[HSPhiZeroMinusPhik,s]=(Sqrt[2Bound[Phi,abs,max,s]Bound[Phi,abs,Delta,s]]);
Bound[HSPhiZeroMinusPhikDk,s]=Bound[HSPhiZeroMinusPhik,s]+Sqrt[4d]Bound[Phi,abs,max,s];

Bound[HSAzeroMinusAk,s]=(1/(1-((z[s])^2)))Bound[HSPhiZeroMinusPhik,s]+((z[s])/(1-((z[s])^2)))Bound[HSPhiZeroMinusPhikDk,s];
,{s,{i,o}}]

To compute the remaining norms we need to compute operator norm of (Subscript[A, k])=Φ(k)Υ(k). We compute the eigenvalues of (Subscript[A, o]) to (1/(1+z))(Φ^ii),((-1)/(1+z))((Φ^ii)-(Φ^(i-i))),((-1)/(1+z))((Φ^ii)+(Φ^ii)-2(Φ^ik)). The biggest of these values equals the operator norm of (Subscript[A, o]). To bound the norm of (Subscript[A, k])for generel k we bound (Subscript[Φ, o])entry-wise by C, (7.5.4) and then bound the norm of the created matrix. As all entries of this matrix are non-negative it is clear biggest eigenvalue is given by the row sum.

Do[
EigenvalueAZero[1,low,s]=(1/(1+z[s]))Max[Bound[Phi,Even,sumi,s],Bound[Phi,Odd,sumi,s]];
EigenvalueAZero[2,low,s]=(1/(1+z[s]))Max[Bound[Phi,Odd,ii,s]+Bound[Phi,Odd,iin,s],Bound[Phi,Even,ii,s]+Bound[Phi,Even,iin,s]];
EigenvalueAZero[3,low,s]=(1/(1+z[s]))Max[Bound[Phi,Odd,ii,s]+Bound[Phi,Odd,iin,s]+2Bound[Phi,Even,ik,s],Bound[Phi,Even,ii,s]+Bound[Phi,Even,iin,s]+2Bound[Phi,Odd,ik,s]];

Bound[OPAZero,low,s]=Max[EigenvalueAZero[1,low,s],EigenvalueAZero[2,low,s],EigenvalueAZero[3,low,s]];
Bound[OPAZero,AV,s]=(1/(1-z[s]))Bound[Phi,abs,sumi,s];
Bound[OPAk,low,s]=(1/(1-z[s]))Bound[Phi,abs,sumi,s];
Bound[OPAk,AV,s]=(1/(1-z[s]))Bound[Phi,abs,sumi,s];
,{s,{i,o}}]

We continue by computing the remaining bound (6.5.27)

Do[
Do[
Bound[OPBZero,t,s]=(1/(1-Bound[OPAZero,t,s]));
Bound[OPBk,t,s]=(1/(1-Bound[OPAk,t,s]));
Bound[HSBZeroMinusBk,t,s]=Bound[OPBZero,t,s]Bound[HSAzeroMinusAk,s]Bound[OPBk,t,s]
,{t,{low,AV}}];
,{s,{i,o}}]

Then we bound the remaining seven terms of  (6.5.10)-(6.5.14):

Do[
Do[
Bound[PiPart,4,t,s]=Bound[EucleadBZeroOneV,t,s]Bound[HSAzeroMinusAk,s]Bound[OPBk,t,s]Bound[EucleadPhiZeroOneV,t,s];
Bound[PiPart,5,t,s]=Bound[EucleadOfVZeroMinusVk,s]Bound[HSBZeroMinusBk,t,s]Bound[EucleadPhiZeroOneV,t,s];
Bound[PiPart,6,t,s]=Bound[EucleadOfVZero,s]Bound[HSBZeroMinusBk,t,s]Bound[HSPhiZeroMinusPhik,s]Bound[EucleadOfVZero,s];
Bound[PiPart,7,t,s]=Bound[EucleadBZeroOneV,t,s]Bound[HSPhiZeroMinusPhik,s]Bound[EucleadOfVZeroMinusVk,s];
Bound[PiPart,8,t,s]=Bound[EucleadOfVZeroMinusVk,s]Bound[OPBk,t,s]Bound[HSPhiZeroMinusPhik,s]Bound[EucleadOfVZero,s];
Bound[PiPart,9,t,s]=Bound[EucleadOfVZero,s]Bound[HSBZeroMinusBk,t,s]Bound[OPPhik,s]Bound[EucleadOfVZeroMinusVk,s];
Bound[PiPart,10,t,s]=Bound[EucleadOfVZeroMinusVk,s] Bound[OPBk,t,s]Bound[OPPhik,s]Bound[EucleadOfVZeroMinusVk,s]
,{t,{low,AV}}];
,{s,{i,o}}]

Finally, we sum these terms to create the required bounds

Do[
Bound[Pi,Delta,low,s]=Bound[PiPart,Main,low,s]-Sum[Bound[PiPart,j,low,s],{j,1,10}];
Bound[Pi,Delta,AV,s]=Bound[PiPart,Main,AV,s]+Sum[Bound[PiPart,j,AV,s],{j,1,10}];
,{s,{i,o}}]
Clear[j,l];

Computation of constants of Proposition 3.3.1

In this section we perform the computations of Section 4.4. to obtain the constances stated in Proposition 3.3.1

(∑_x)|F(x)|≤  (Subscript[K, F])=Bound[KF]
(∑_x)F(x)[1-cos(k x)]≥ (Subscript[K, Lower])[1-(OverHat[D])(k)]
(∑_x)|F(x)|[1-cos(k x)]≤  (Subscript[K, ΔF])[1-(OverHat[D])(k)]

and recall that this Φ was trivial for this expansion

(Subscript[(UnderBar[K]), Φ])=(OverHat[Φ])(0)= (Subscript[(OverBar[K]), Φ])=(Subscript[(UnderBar[K]), |Φ|])=(∑_x)|Φ(x)|=  (Subscript[(OverBar[K]), |Φ|])=1
(∑_(x≠0))|(Subscript[Φ, z])(x)|≤  (Subscript[K, |Φ|])=0
(∑_x)|(Subscript[Φ, z])(x)|[1-cos(k x)]≤  (Subscript[K, ΔΦ])[1-(OverHat[D])(k)]=0

Computation of the constants

Bound on the values as given in Section 4.4.2, thereby we recall that this Phi was trivail:

Do[
Bound[KF, s]=2d z[s]+Bound[Pi,upper,s];
Bound[KDeltaFLower, s]=(1/(2d z[i]+Bound[Pi,Delta,low,s]));
Bound[KDeltaF, s]=2d z[o]+Bound[Pi,Delta,AV,s];
,{s,{i,o}}]

Check of the sufficient condition

Now we can compute whether P(γ,Γ,z) is satisfied, see Definition 3.3.2.

LEf1Bound[i]=1;
LEf1Bound[o]=(((2d-1))/(2d))(1-Bound[Pi,lower,o]);

LEf2Bound[i]=((2d-1)/(2d-2))Bound[KDeltaFLower,i];
LEf2Bound[o]=((2d-1)/(2d-2))Bound[KDeltaFLower,o];

Can compute the bound on (Subscript[f, 3]):

Do[
LEf3Bound[Part2,s]=If[c2≤0,1000,(1/(2 c2))Bound[KDeltaF,s]((Bound[KDeltaFLower,s])^2)];
LEf3Bound[Part4,s]=If[c4≤0,1000,(4/c4)((Bound[KDeltaFLower,s])^3)((Bound[KDeltaF,s])^2)];
LEf3Bound[s]=Max[LEf3Bound[Part2,s],LEf3Bound[Part4,s]];
,{s,{i,o}}]

Do[
Succes[f1,s]=LEf1Bound[s]<Gamma1;
Succes[f2,s]=LEf2Bound[s]<Gamma2;
Succes[f3,s]=LEf3Bound[s]<Gamma3;
Succes[s]=Succes[f1,s]&&Succes[f2,s]&& Succes[f3,s];
,{s,{i,o}}]
Succes[overall]=Succes[i]&&Succes[o];

Outputs

The overall result

The statement that the bootstrap was succesful is

Succes[overall]

If this succedes than the analysis of Section 4.3 can be used to proved mean-field behavoior for SAW.

Assuming the bootstrap was succesful we prove the following bounds: The infrared bound in (3.3.12) and (3.3.13) hold with

((2d-2)/(2d-1))Gamma2(* ≥ (Subscript[G, z])(k)[1-(OverHat[D])(k)]*)
Bound[KDeltaFLower,o](* Nominator in (4.3.13) *)

Further we have proven that (Subscript[z, c]) is smaller than

(1/(2d-1))Gamma1

The improvement of bounds

bubbles={Graphics[{Green,Disk[{0,0},0.8]},ImageSize-> 40],Graphics[{Red,Disk[{0,0},0.8]},ImageSize-> 40]};
MethodeFourTablePart3={{Quantity,F1,F2,F3Part2,F3Part4,F2-init,F3-init},{"To beat",Gamma1,Gamma2,Gamma3,Gamma3,Gamma2,Gamma3},{Computed,LEf1Bound[o],LEf2Bound[o],LEf3Bound[Part2,o],LEf3Bound[Part4,o],LEf2Bound[i],LEf3Bound[i]},{check, If[Succes[f1,o],bubbles[[1]],bubbles[[2]]],If[Succes[f2,o],bubbles[[1]],bubbles[[2]]],If[LEf3Bound[Part2,o]<Gamma3,bubbles[[1]],bubbles[[2]]],If[LEf3Bound[Part4,o]<Gamma3,bubbles[[1]],bubbles[[2]]],If[Succes[f2,i],bubbles[[1]],bubbles[[2]]],If[LEf3Bound[i]<Gamma3,bubbles[[1]],bubbles[[2]]]},{Required (Subscript[c, i]),,,LEf3Bound[Part2,o]*c2/Gamma3,LEf3Bound[Part4,o]*c4/Gamma3},{given (Subscript[c, i]) ,,,c2,c4}};Labeled[Grid[MethodeFourTablePart3,Alignment->{Center},Frame->True,Dividers->{{2->True,-1->True},{2->True}},ItemStyle->{1->Bold,1->Bold},Background->{{None},{GrayLevel[0.9]},{None}}],Style["Bound on coefficients in Dimension "Text[d],Bold],Top]//Text

The table above shows whether the improvement of bound for the function (Subscript[f, i]) was succesfull. As the bound on (Subscript[f, 3]) is the hardest to improve we show both parts. To be able to choose the value of (Subscript[c, i]) correctly me mark the required values in the table.