Computation for the lace expansion for lattice animals

Analysis of Section 3.3

Robert Fitzner

In this file we performs the numerical part of the analysis of the non-backtracking lace expansion for lattice animals. All references in this version of the notebook will be to the PhD thesis of the author.

We expects as input the dimension d and the constance (Subscript[Γ, 1]),(Subscript[Γ, 2]),(Subscript[Γ, 3]), (Subscript[c, 1]),..,(Subscript[c, 4]). After choosing these quantities the used should select the menu item Evaluate-> Evaluate Notebook. In a table at the end of this document the result of the computations are shown. There it can be see whether the bootstrap with the given parameters and therefore the analysis was succesful.

We first compute bounds on the simple random walk two-point function (Section 5.2.1). Then we compute bound on the two-point function and repulsive diagrams (Section 5.1.2). We use these bounds to compute the Diagramatic bounds derived in Section 4.4. and compute the bounds used for the Analysis in Section 3.3. The document corresponds to 95% to the file for LTs.

8.05.2013

Input

The dimension in which we perfrom the computations

d=49;

For the bootstrap we assume that (Subscript[f, i])(z)≤ (Subscript[Γ, i]) with (Subscript[Γ, i]) gives as follows

Gamma1=1.01843;
Gamma2=1.14144;
Gamma3=1.2;

For the bootstrap function (Subscript[f, 3]) we use the following constants

c1=0.075649769;
c2=0.657045244;
c3=0.10758573345;
c4=7.2943655;

Value for which it works:

(*Gamma1=1.01843;
Gamma2=1.14144;
Gamma3=1.2;
c1=0.075649769;
c2=0.657045244;
c3=0.10758573345;
c4=7.2943655;*)

Simple Random Walk integral

We compute the two-point function of the simple random walk,

(Subscript[I, n,m])(x)=(∫_([ -ℼ,ℼ]))(e^(ik x))((((OverHat[D])^m) (k))/(((1-(OverHat[D])(k)))^n))(((d^d)k)/(((2π))^d))

see Section 5.2, using that

(Subscript[I, n,m])(x)=(Subscript[I, n,(m-1)])(x)-(Subscript[I, (n-1),(m-1)])(x)
(Subscript[I, n,0])(x)=(1/((n-1)!))(∫_0^∞)(t^(n-1))(∏_(i=1)^d)(∫_(-π)^π)(e^(-t/d(1-cos((Subscript[k, i]))))(e^((Subscript[ιk, i])(Subscript[x, i])))(dk/(2π)) =(1/((n-1)!))(∫_0^∞)(t^(n-1))(∏_(i=1)^d)F(t,d,(Abs[(Subscript[x, i])]))

where F(t,d,n) is the modified Besselfunction. We implement the Besselfunciton and a function to compute (Subscript[I, n,0])(x).

F[t_,d_,N_]:= (E^(-(t/d))) BesselI[N,(t/d)];
NInt[n_,d_,T_]:=1/((n-1)!)*NIntegrate[t^(n-1)*(F[t,d,0])^d,{t,0,T},WorkingPrecision->40];

Then we define the number of n-step SRW loop as given in Section (5.2.6)-(5.2.10)

s2=N[2d];
s4=N[(d*((4!)/(2 2))+((d(d-1))/2)*4!)];
s6=N[ (d*((6!)/(3!3!))+d*(d-1)*((6!)/(2 2))+((d(d-1)(d-2))/(3!))*6!)];
s8=N[(d*((8!)/(4!4!))+d*(d-1)*(((8!)/(3!3!))+((8!)/(2^5)))+((d(d-1)(d-2))/2)*((8!)/(2 2))+((d(d-1)(d-2)(d-3))/(4!))*8!)];

Then we compute (Subscript[I, n,0])(0) for n=1,2,3,4:

I10=NInt[1,d,∞];
I20=NInt[2,d,∞];
I30=NInt[3,d,∞];
I40=NInt[4,d,∞];

and use (Subscript[I, n,m])(0)=(Subscript[I, n,(m-1)])(0)-(Subscript[I, (n-1),(m-1)])(0) to compute (Subscript[I, n,m])(0):

SRWTwoPointFunctionTable = {{ n m,0, 1, 2, 3, 4}, {0,1, I10, I20, I30, I40}, {1,0,0,0, 0, 0}, {2,(s2/(((2d))^2)), 0,0, 0,0}, {3,0, 0,0, 0, 0}, {4,(s4/(((2d))^4)), 0,0, 0, 0},{5, 0,0,0, 0, 0},{6,(s6/(((2d))^6)),0,0, 0, 0},{7, 0,0,0, 0, 0},{8,(s8/(((2d))^8)),0,0, 0, 0},{9, 0,0,0, 0, 0},{10,-1,0,0, 0, 0}};
For[i=3,i<13,i++,
For[j=3,j<7,j++,
SRWTwoPointFunctionTable[[i,j]]=SRWTwoPointFunctionTable[[i-1,j]]-SRWTwoPointFunctionTable[[i-1,j-1]];]
]
Clear[i,j]

I11=SRWTwoPointFunctionTable[[3,3]];
I12=SRWTwoPointFunctionTable[[4,3]];
I14=SRWTwoPointFunctionTable[[6,3]];
I16=SRWTwoPointFunctionTable[[8,3]];
I16=SRWTwoPointFunctionTable[[8,3]];
I18=SRWTwoPointFunctionTable[[10,3]];
I110=SRWTwoPointFunctionTable[[12,3]];
I21=SRWTwoPointFunctionTable[[3,4]];
I22=SRWTwoPointFunctionTable[[4,4]];
I24=SRWTwoPointFunctionTable[[6,4]];
I26=SRWTwoPointFunctionTable[[8,4]];
I28=SRWTwoPointFunctionTable[[10,4]];
I210=SRWTwoPointFunctionTable[[12,4]];
I31=SRWTwoPointFunctionTable[[3,5]];
I32=SRWTwoPointFunctionTable[[4,5]];
I33=SRWTwoPointFunctionTable[[5,5]];
I34=SRWTwoPointFunctionTable[[6,5]];
I36=SRWTwoPointFunctionTable[[8,5]];
I38=SRWTwoPointFunctionTable[[10,5]];
I310=SRWTwoPointFunctionTable[[12,5]];
I42=SRWTwoPointFunctionTable[[4,6]];
I44=SRWTwoPointFunctionTable[[6,6]];
I46=SRWTwoPointFunctionTable[[8,6]];
I48=SRWTwoPointFunctionTable[[8,6]];
I410=SRWTwoPointFunctionTable[[12,6]];

NForm[a_]:=NumberForm[N[a] ,5];
Labeled[Grid[Map[NForm,SRWTwoPointFunctionTable,{2}], Alignment -> {{Left, Center}, Baseline, {{2, 12}, {2, 6}} -> {"."}}, Frame -> True, Dividers -> {{2 -> True, -1 -> True}, {2 -> True}}, Spacings -> {1.5, {1.5, 1, {0.5}}}, ItemStyle -> {1 -> Bold, 1 -> Bold}, Background -> {Automatic, Automatic, {{2, 12}, {2, 6}} -> GrayLevel[0.9]}], Style["Value of the SRW two-point function.", Bold], Top] // Text

Bound on the two-point function and on repulsive diagrams

Definition of Constants

We define the constants for two setting s: we use s=i for bound on z=(Subscript[z, I]) and s=o for bound on zϵ ((Subscript[z, I]),(Subscript[z, c])): For z=(Subscript[z, I]), we use the following relations,  that are proven in Section 3.6.2.

(Subscript[z, I])=(1/((2d -1)e))
(Subscript[g, (Subscript[z, I])])≤ e+((e-1)/(2d-1))
(Subscript[g, (Subscript[z, I])]^i)≤ 1+((Subscript[g, (Subscript[z, I])])-1)((2d-1)/(2d))≤ e   
(Subscript[G, z])(x)≤(Subscript[g, (Subscript[z, I])]^i)(Subscript[B, (Subscript[z, I])(Subscript[g, (Subscript[z, I])]^i)])(x)≤ (Subscript[g, (Subscript[z, I])]^i)((2d-2)/(2d-1))C(x)
(Subscript[(OverTilde[G]), z])(x)≤(Subscript[B, (Subscript[z, I])(Subscript[g, (Subscript[z, I])]^i)])(x)≤((2d-2)/(2d-1))C(x).

For z ϵ ((Subscript[z, I]),(Subscript[z, c])) we know that

2d z (Subscript[g, z]^i)<2d (Subscript[g, z])z<(Subscript[Γ, 1])
(Subscript[g, z])<e (Subscript[Γ, 1]) for all z≥ (1/((2d-1)e))
(Subscript[g, z]^i)<1+((Subscript[g, z])-1)((2d-1)/(2d))

In the following we implement the basic quantities for the status i at (Subscript[z, I]) and the status o for z in ((Subscript[z, I]),(Subscript[z, c])), which will allows us to implement the bound for both (s=i,o) with the same code

g[i]=Exp[1]+((Exp[1]-1)/(2d-1));
g[o]=Exp[1]*Gamma1;
gj[i]=Exp[1];
gj[o]=1+(g[o]-1)*((2d-1)/(2d));
rho[i]=((gj[i])/(g[i]));
rho[o]=((gj[o])/(g[o]));
twodgz[i]=2d (1/((2d -1 )Exp[1]))g[i];
twodgz[o]= ((2d)/(2d-1)) Gamma1;
twodgjz[i]=((2d)/(2d-1));
twodgjz[o]= ((2d)/(2d-1)) Gamma1;
gjz[i]=(1/(2d-1));
gjz[o]= (1/(2d-1)) Gamma1;

VarGamma1[i]=(1+((1-Exp[-1])/(2d-1)));
VarGamma1[o]=Gamma1;
VarGamma2[i]=rho[i]*(((2d-2))/(2d-1)); (*(Subscript[G, z])(x)≤(Subscript[g, z])(Subscript[B, (Subscript[zg, z])])(x)≤ (Subscript[g, z])((2d-2)/(2d-1))C(x)*)
VarGamma2[o]=Gamma2*((2d-2)/(2d-1)); (*(Subscript[(OverHat[G]), z])(k)≤ ConstantGvsC (OverHat[C])(k), follows from f2*)
VarGamma3[i]=1; (*We bound a weighted line by replacing the tree two-point function with a normal on*)
VarGamma3[o]=Gamma3;(*(Subscript[(OverHat[G]), z])(k)≤ (OverHat[C])(k)*)
Varc1[o]=c1; Varc2[o]=c2; Varc3[o]=c3; Varc4[o]=c4;
Varc1[i]=0; Varc2[i]=0.5; Varc3[i]=0; Varc4[i]=4;

Further, we define variables to save the number of short SAWs, as given in Section 5.1.3

c2ik=2; (*(Subscript[c, 2])((Subscript[e, 1])+(Subscript[e, 2]))*)
c4ik=4(2d-3)+2(2d-4);(*(Subscript[c, 4])((Subscript[e, 1])+(Subscript[e, 2]))*)
c6ik=16+84(2d-4)+36(2d-4)(2d-6)+ 6d c3i;(*(Subscript[c, 4])((Subscript[e, 1])+(Subscript[e, 2]))*)

c3i=(2d-2);(*(Subscript[c, 3])((Subscript[e, 1]))*)
c5i=(3(2d-2 )+4(2d-2)(2d-4) );(*(Subscript[c, 5])((Subscript[e, 1]))*)
c7i=(14(2d-2 )+62(2d-2)(2d-4)+27(2d-2)(2d-4)(2d-6) )+8d c3i+4d c5i;(*(Subscript[c, 7])((Subscript[e, 1]))*)

Bounds on two-point function

We compute bounds as explained in Section 5.1.2. We begin by computing (Subscript[G, n,z])((Subscript[e, 1])) as in (5.1.22)-(5.1.24)

Do[
Bound[tG7i,s]=c7i (((gjz[s]))^7)+(twodgjz[s])^9*VarGamma2[s]*I110;(* (Subscript[G, 7,z])((Subscript[e, 1]))*)
Bound[tG5i,s]=c5i (((gjz[s]))^5)+Bound[tG7i,s];(* (Subscript[G, 5,z])((Subscript[e, 1]))*)
Bound[tG3i,s]=c3i (((gjz[s]))^3)+Bound[tG5i,s];(* (Subscript[G, 3,z])((Subscript[e, 1]))*)
Bound[tG1i,s]=gjz[s]+Bound[tG3i,s];(* (Subscript[G, 1,z])((Subscript[e, 1]))*)
,{s,{i,o}}]

Then we compute (Subscript[G, n,z])((Subscript[e, 1])+(Subscript[e, 2])) and (Subscript[G, 4,z])(2(Subscript[e, 2])), see (5.1.25)-(5.1.26) :

Do[
Bound[tG8ik,s]=(d/(d-1))(twodgjz[o])^8VarGamma2[s]I110;(*(Subscript[G, 8])((Subscript[e, 1])+(Subscript[e, 2]))*)
Bound[tG6ik,s]=c6ik gjz[s]^6+VarGamma2[s]I18;(*(Subscript[G, 6])((Subscript[e, 1])+(Subscript[e, 2]))*)
Bound[tG4ik,s]=Bound[tG6ik,s]+(c4ik-2(2d-3) )((gjz[s])^4);(*(Subscript[G, 4]^1)((Subscript[e, 1])+(Subscript[e, 2]))*)
Bound[tG2ik,s]=Bound[tG4ik,s]+(c2ik-1)((gjz[s])^2);(*(Subscript[G, 2]^1)((Subscript[e, 1])+(Subscript[e, 2]))*)
(*Bound[tG4ii,s]=(2d+2)((gjz[s])^4)+Bound[tG6,s];(* Bound for (sup_x)(Subscript[G, 4]^1)(2 (Subscript[e, 1]))*)*)
,{s,{i,o}}]

We compute the supreme of the two-point function as given in (5.1.27)-(5.1.31):

Do[
Bound[tG6,s]=Max[c6ik ((gjz[s])^6),c7i ((gjz[s])^7)]+(twodgjz[s])^8VarGamma2[s]I18;  (* Bound for (sup_x)(Subscript[G, 6])(x)*)
Bound[tG4,s]=Max[c4ik ((gjz[s])^4),c5i ((gjz[s])^5)]+Bound[tG6,s]; (* Bound for (sup_x)(Subscript[G, 4])(x)*)
Bound[tG2,s]=Max[c2ik ((gjz[s])^2),c3i ((gjz[s])^3)]+Bound[tG4,s]; (* Bound for (sup_x)(Subscript[G, 2])(x)*)
Bound[tG1,s]=Max[Bound[tG1i,s],Bound[tG2,s]];(* Bound for (sup_x)(Subscript[G, 1])(x)*)
,{s,{i,o}}]

Closed repulsive diagrams

We define the bounds on the closed repulsive diagrams as desribed in Section 5.1.2 in (5.1.34)-(5.1.36). The bound does only depent on the total number of steps and the number of tw-point functions involved. It does not depent on the indivitual length of the pieces (Subscript[m, 1]),(Subscript[m, 2]),... and of the orientation of the arrows.

Do[
Bound[ClosedRepLoop,4,s]=twodgjz[s]Bound[tG3i,s];
Bound[ClosedRepBubble,4,s]=((gjz[s])^4)(2d c3i)+3((gjz[s])^6)(2d c5i)+5((gjz[s])^8)(2d c7i)+ 6((twodgjz[s])^10)VarGamma2[s]I110+((twodgjz[s])^10)((VarGamma2[s])^2)I210;
Bound[ClosedRepBubble,3,s]=Bound[ClosedRepLoop,4,s]+Bound[ClosedRepBubble,4,s];
Bound[ClosedRepTriangle,4,s]=(((4+1-4)(4+2-4))/2)((gjz[s])^4)(2d c3i)+(((6+1-4)(6+2-4))/2)((gjz[s])^6)(2d c5i)+(((8+1-4)(8+2-4))/2)((gjz[s])^8)(2d c7i)+ (((10-4)(9-4))/2)((twodgjz[s])^10)VarGamma2[s]I110+6 ((twodgjz[s])^10)((VarGamma2[s])^2)I210+((twodgjz[s])^10)((VarGamma2[s])^3)I310;
Bound[ClosedRepTriangle,3,s]=Bound[ClosedRepTriangle,4,s]+Bound[ClosedRepBubble,3,s];
Bound[ClosedRepTriangle,2,s]=Bound[ClosedRepTriangle,3,s]+Bound[ClosedRepBubble,3,s]+Bound[ClosedRepLoop,4,s];
Bound[ClosedRepSquare,4,s]=((gjz[s])^4)(2d c3i)+10((gjz[s])^6)(2d c5i)+35((gjz[s])^8)(2d c7i)+ 84((twodgjz[s])^10)VarGamma2[s]I110 +(((10-4)(9-4))/2)((twodgjz[s])^10)((VarGamma2[s])^2)I210+6((twodgjz[s])^10)((VarGamma2[s])^3)I310+((twodgjz[s])^10)((VarGamma2[s])^4)I410;
,{s,{i,o}}]

Open repulsive diagrams

Then we define the bound on the open repulsive diagrams as in (5.1.38):

Do[
Bound[OpenRepBubble,2,s]=Max[c2ik ((gjz[s])^2)+3c4ik ((gjz[s])^4)+5c6ik ((gjz[s])^6),2c3i ((gjz[s])^3)+4c5i ((gjz[s])^5)+6c7i ((gjz[s])^7)] +6((twodgjz[s])^8)VarGamma2[s]I18+((twodgjz[s])^8)((VarGamma2[s])^2)I28;
Bound[OpenRepBubble,3,s]=Max[2c4ik ((gjz[s])^4)+4c6ik ((gjz[s])^6),c3i ((gjz[s])^3)+3c5i ((gjz[s])^5)+5c7i ((gjz[s])^7)] +5((twodgjz[s])^8)VarGamma2[s]I18+((twodgjz[s])^8)((VarGamma2[s])^2)I28;
Bound[OpenRepBubble,4,s]=Max[c4ik ((gjz[s])^4)+3c6ik ((gjz[s])^6),c5i ((gjz[s])^5)+4c7i ((gjz[s])^7)] +4((twodgjz[s])^8)VarGamma2[s]I18+((twodgjz[s])^8)((VarGamma2[s])^2)I28;
Bound[OpenRepTriangle,1,s]=Max[3c2ik ((gjz[s])^2)+10c4ik ((gjz[s])^4)+21c6ik ((gjz[s])^6),gjz[s]+6c3i ((gjz[s])^3)+15c5i ((gjz[s])^5)+28c7i ((gjz[s])^7)] +(((8-1)(7-1))/2)((twodgjz[s])^8)VarGamma2[s]I18+7((twodgjz[s])^8)((VarGamma2[s])^2)I28+((twodgjz[s])^8)((VarGamma2[s])^3)I38;
Bound[OpenRepTriangle,2,s]=Max[c2ik ((gjz[s])^2)+6c4ik ((gjz[s])^4)+15c6ik ((gjz[s])^6),3c3i ((gjz[s])^3)+10c5i ((gjz[s])^5)+21c7i ((gjz[s])^7)] +(((8-2)(7-2))/2)((twodgjz[s])^8)VarGamma2[s]I18+6((twodgjz[s])^8)((VarGamma2[s])^2)I28+((twodgjz[s])^8)((VarGamma2[s])^3)I38;
Bound[OpenRepTriangle,3,s]=Max[3c4ik ((gjz[s])^4)+10c6ik ((gjz[s])^6),c3i ((gjz[s])^3)+6c5i ((gjz[s])^5)+15c7i ((gjz[s])^7)] +(((8-3)(7-3))/2)((twodgjz[s])^8)VarGamma2[s]I18+5((twodgjz[s])^8)((VarGamma2[s])^2)I28+((twodgjz[s])^8)((VarGamma2[s])^3)I38;
Bound[OpenRepSquare,3,s]=Max[4c4ik ((gjz[s])^4)+20c6ik ((gjz[s])^6),c3i ((gjz[s])^3)+10c5i ((gjz[s])^5)+35c7i ((gjz[s])^7)] +56((twodgjz[s])^8)VarGamma2[s]I18+(((8-3)(7-3))/2)((twodgjz[s])^8)((VarGamma2[s])^2)I28+5((twodgjz[s])^8)((VarGamma2[s])^3)I38+((twodgjz[s])^8)((VarGamma2[s])^4)I48;
,{s,{i,o}}]

Weighted Diagrams

We define weighted diagams as explained in Section 5.1., e.g. (5.1.19) and (5.1.42)-(5.1.49) we derive weighted closed diagrams

Do[
Bound[WeightedClosedBubble,4,s]=((twodgjz[s])^4)VarGamma2[s]VarGamma3[s](Varc1[s]I24+(2Varc2[s]+Varc3[s])I34);
Bound[WeightedClosedBubble,2,s]=Bound[WeightedClosedBubble,4,s]+8d ((gjz[s])^2)(((gjz[s])^4)(2d-2)*2+Bound[tG6,s])+8d ((gjz[s])^2)(2d-2)(((gjz[s])^2)+Bound[tG4ik,s])+2d ((gjz[s])^3)( Bound[tG3i,s]+3 (2d-2)(d/(d-1))(d/(d-2))((twodgjz[s])^3)VarGamma2[s]I16+ 5(2d-2)(d/((d-1)))Bound[tG6,s]+ 9(((gjz[s])^2)+3(2d-2)((gjz[s])^5)+Bound[tG6,s]));
Bound[WeightedClosedBubble,0,s]=Bound[WeightedClosedBubble,2,s]+twodgjz[s] Bound[tG3i,s];


Bound[WeightedClosedTriangle,4,s]=((twodgjz[s])^2)((VarGamma2[s])^2)VarGamma3[s](Varc1[s]I34+(2Varc2[s]+Varc3[s])I44);
Bound[WeightedClosedTriangle,2,s]=2Bound[WeightedClosedBubble,4,s]+Bound[WeightedClosedTriangle,4,s]+8d ((gjz[s])^2)(((gjz[s])^4)(2d-2)*2+Bound[tG6,s])+8d ((gjz[s])^2)(2d-2)(((gjz[s])^2)+Bound[tG4ik,s])+4d ((gjz[s])^3)( Bound[tG3i,s]+3 (2d-2)(d/(d-1))(d/(d-2))((twodgjz[s])^3)VarGamma2[s]I16+ 5(2d-2)(d/((d-1)))Bound[tG6,s]+ 9(((gjz[s])^2)+3(2d-2)((gjz[s])^5)+Bound[tG6,s]));

,{s,{i,o}}]

Then we bound the open diagram using (5.1.19), for a odd number we used Chauchy-Schwarz to obtain an improved bound

Do[
Bound[WeightedOpenBubble,0,s]=VarGamma2[s]VarGamma3[s](Varc1[s]I20+(2Varc2[s]+Varc4[s])I30);
Bound[WeightedOpenBubble,2,s]=((twodgjz[s])^2)VarGamma2[s]VarGamma3[s](Varc1[s]I22+(2Varc2[s]+Varc4[s])I32);
Bound[WeightedOpenBubble,1,s]=twodgjz[s]VarGamma2[s]VarGamma3[s]√((Varc1[s]I20+(2Varc2[s]+Varc4[s])I30)(Varc1[s]I22+(2Varc2[s]+Varc4[s])I32));
Bound[WeightedOpenBubble,3,s]=((twodgjz[s])^3)VarGamma2[s]VarGamma3[s]√((Varc1[s]I22+(2Varc2[s]+Varc4[s])I32)(Varc1[s]I24+(2Varc2[s]+Varc4[s])I34));


Bound[WeightedOpenTriangle,0,s]=((VarGamma2[s])^2)VarGamma3[s](Varc1[s]I30+(2Varc2[s]+Varc4[s])I40);
Bound[WeightedOpenTriangle,2,s]=((twodgjz[s])^2)((VarGamma2[s])^2)VarGamma3[s](Varc1[s]I32+(2Varc2[s]+Varc4[s])I42);
Bound[WeightedOpenTriangle,1,s]=twodgjz[s]((VarGamma2[s])^2)VarGamma3[s]√((Varc1[s]I30+(2Varc2[s]+Varc4[s])I40)(Varc1[s]I32+(2Varc2[s]+Varc4[s])I42));
Bound[WeightedOpenTriangle,3,s]=((twodgjz[s])^3)((VarGamma2[s])^2)VarGamma3[s]√((Varc1[s]I32+(2Varc2[s]+Varc4[s])I42)(Varc1[s]I34+(2Varc2[s]+Varc4[s])I44));
,{s,{i,o}}]

We define the elements as given in (4.3.31)-(4.3.37)  and (4.3.49)-(4.3.51)

Do[
Bound[Delta,I,0,s]=2 twodgjz[s]Bound[tG3i,s]+2Bound[WeightedClosedBubble,2,s]+Bound[WeightedClosedTriangle,2,s];
Bound[Delta,I,1,s]=Bound[tG3i,s]+((Bound[WeightedClosedBubble,2,s])/(twodgjz[s]))+((Bound[WeightedClosedTriangle,2,s])/(twodgjz[s]));
Bound[Delta,I,2,s]=Bound[WeightedOpenTriangle,0,s];
Bound[Delta,I,3,s]=2((Bound[WeightedOpenBubble,2,s])/(twodgjz[s]))+2((Bound[WeightedOpenTriangle,3,s])/(twodgjz[s]));
Bound[Delta,I,4,s]=Bound[WeightedOpenBubble,1,s]+((Bound[WeightedOpenBubble,2,s])/(twodgjz[s]))+2((Bound[WeightedOpenTriangle,2,s])/(twodgjz[s]));
Bound[Delta,I,5,s]=((Bound[WeightedClosedTriangle,2,s])/((twodgjz[s])^2));
Bound[Delta,I,6,s]=2Bound[WeightedClosedBubble,2,s]+Bound[WeightedClosedTriangle,4,s];

Bound[Delta,II,0,s]=twodgjz[s]Bound[tG3i,s]+Bound[WeightedClosedBubble,2,s]+Bound[WeightedClosedTriangle,2,s];
Bound[Delta,II,1,s]=((Bound[WeightedClosedTriangle,2,s])/(twodgjz[s]));
Bound[Delta,II,2,s]=Bound[WeightedOpenTriangle,1,s];
,{s,{i,o}}]

Bound on the coefficients

Definition of Initial Pieces (P ,(P^ι))

To implement the bound of N≥1 we define the boulding matricies given in (4.3.27)-(4.3.53):

Do[
(* definition of first peices, inpendent of fiota*)
Bound[P1,0,0,s]=(3Bound[ClosedRepLoop,4,s]+3Bound[ClosedRepBubble,4,s]+Bound[ClosedRepTriangle,4,s]);
Bound[P1,0,1,s]=(2Bound[ClosedRepLoop,4,s]+Bound[ClosedRepBubble,4,s]+Bound[ClosedRepTriangle,4,s]);
Bound[P1,0,2,s]=(Bound[ClosedRepLoop,4,s]+Bound[ClosedRepBubble,4,s]+Bound[ClosedRepTriangle,4,s]+Bound[ClosedRepSquare,4,s]);
Bound[P1,0,-1,s]=(Bound[ClosedRepLoop,4,s]+2Bound[ClosedRepBubble,4,s]+Bound[ClosedRepTriangle,4,s]);
Bound[P1,0,-2,s]=(Bound[ClosedRepTriangle,4,s]+Bound[ClosedRepSquare,4,s]);;
(* definition of first peices, first step of the backbone goes to (Subscript[e, i])*)
Do[Bound[P1,IotaStep,t,s]=Bound[P1,0,t,s],{t,{-2,-1,0,1,2}}];
Bound[P1,IotaRib,0,s]=2d(Bound[tG1i,s]Bound[P1,0,0,s] +Bound[ClosedRepBubble,4,s]+2Bound[tG2,s]Bound[ClosedRepLoop,4,s]+Bound[tG1,s]Bound[ClosedRepBubble,4,s]+Bound[tG3i,s](1/(twodgjz[s]))Bound[ClosedRepBubble,3,s]+(((Bound[ClosedRepBubble,4,s]))/(twodgjz[s]))Bound[OpenRepBubble,2,s] (*c≠x,(Subscript[d, omega])=1*)+2Bound[OpenRepBubble,3,s](Bound[tG1i,s]+(1/(twodgjz[s]))Bound[ClosedRepBubble,3,s])(*c≠x,(Subscript[d, omega])≥ 2;u≠v=x*)+Bound[OpenRepTriangle,3,s](Bound[tG1i,s]+(1/(twodgjz[s]))Bound[ClosedRepBubble,3,s])(*u≠v≠x*));
(*definition of the first piece if (Subscript[e, i]) is somewhere on the first rib*)
Bound[P1,IotaRib,1,s]=2d(Bound[tG1i,s]Bound[P1,0,1,s] +Bound[ClosedRepBubble,4,s]+Bound[ClosedRepBubble,4,s]+Bound[ClosedRepTriangle,4,s]+(1/(twodgjz[s]))Bound[ClosedRepBubble,3,s]Bound[OpenRepBubble,2,s]+(Bound[tG1i,s]+(1/(twodgjz[s]))Bound[ClosedRepBubble,3,s])Bound[OpenRepTriangle,3,s]);
Bound[P1,IotaRib,2,s]=2d(Bound[tG1i,s]Bound[P1,0,2,s] +(Bound[tG1i,s]+(1/(twodgjz[s]))Bound[ClosedRepBubble,3,s])Bound[OpenRepSquare,3,s]);
Bound[P1,IotaRib,-2,s]=2d(Bound[tG1i,s]Bound[P1,0,-2,s] +(Bound[tG1i,s]+(1/(twodgjz[s]))Bound[ClosedRepBubble,3,s])Bound[OpenRepSquare,3,s]);
Bound[P1,IotaRib,-1,s]=2d(Bound[tG1i,s]Bound[P1,0,-1,s] +Bound[tG1,s](Bound[ClosedRepLoop,4,s]+Bound[ClosedRepBubble,4,s]+Bound[ClosedRepTriangle,4,s])+(Bound[tG1i,s]+(1/(twodgjz[s]))Bound[ClosedRepBubble,3,s])Bound[OpenRepTriangle,3,s]);
,{s,{i,o}}]

Definition of Initial Pieces (Q, (Q^ι) )

Now we define the vectors for the first diagram of the coefficients (4.4.6)-(4.4.23)

Do[
(* definition of first pieces, inpendent of fiota*)
Bound[Q0,0,s]=Bound[ClosedRepLoop,4,s]+Bound[ClosedRepBubble,4,s];
Bound[Q0,1,s]=Bound[tG3i,s]+Bound[ClosedRepBubble,4,s];
Bound[Q0,2,s]=Bound[ClosedRepBubble,4,s]+Bound[ClosedRepTriangle,4,s];

Do[ (*Line (4.4.10) *)
Bound[Q1,t,s]=Bound[P1,0,t,s]+Sum[Bound[Q0,r,s]Bound[A,-r,t,s],{r,0,2}];
,{t,{-2,-1,0,1,2}}];
Bound[Q0,sausage,p1,0,s]=Bound[tG3i,s]Bound[tG1i,s]+Bound[ClosedRepBubble,3,s]((Bound[tG1i,s])/( gjz[s]))+Bound[tG2,s](Bound[ClosedRepLoop,4,s]+Bound[ClosedRepBubble,3,s])+Bound[tG1,s](Bound[ClosedRepBubble,4,s]+Bound[ClosedRepTriangle,4,s]);
Bound[Q0,sausage,0,s]=Bound[tG1i,s]Bound[Q0,0,s]+Bound[Q0,sausage,p1,0,s];
Bound[Q0,sausage,p1,1,s]=Bound[tG1i,s]Bound[Q0,1,s]+Bound[ClosedRepBubble,3,s]((Bound[tG1i,s])/( gjz[s]))+(Bound[ClosedRepLoop,4,s]+Bound[ClosedRepBubble,3,s])((Bound[tG1i,s])/( gjz[s]))+
Bound[tG2,s](Bound[ClosedRepBubble,3,s]+Bound[ClosedRepLoop,4,s]+Bound[ClosedRepBubble,3,s])+Bound[tG1,s](Bound[ClosedRepTriangle,4,s]+Bound[ClosedRepTriangle,3,s]);
Bound[Q0,sausage,1,s]=Bound[tG1i,s]Bound[Q0,1,s]+Bound[Q0,sausage,p1,1,s];
Bound[Q0,sausage,p1,2,s]=(2 Bound[ClosedRepTriangle,3,s]+Bound[ClosedRepBubble,3,s])((Bound[tG1i,s])/( gjz[s]))+Bound[tG1,s]Bound[ClosedRepSquare,4,s]+Bound[tG2,s]Bound[ClosedRepTriangle,3,s]+ Bound[tG1,s]Bound[ClosedRepSquare,4,s];
Bound[Q0,sausage,2,s]=Bound[tG1i,s]Bound[Q0,2,s]+Bound[Q0,sausage,p1,2,s];
Do[ (*Line (4.4.14) *)
Bound[Q1,sausage,t,s]=Sum[Bound[Q0, sausage,r,s]Bound[A,-r,t,s],{r,0,2}];
(* improvement ot (4.4.22)*)
Bound[Q1,step,t,s]=(((gjz[s])^2)+Bound[tG4ik,s])Bound[tG4ik,s](Bound[A,0,t,s]+2Bound[A,-1,t,s])+Bound[ClosedRepBubble,4,s]((Bound[tG2ik,s])/( gjz[s]))Bound[A,-2,t,s];
(* improvement ot (4.4.23)*)
Bound[Q1,iota,t,s]=Bound[P1,IotaStep,t,s]+Bound[P1,IotaRib,t,s]+Bound[Q1,sausage,t,s]+Bound[Q1,step,t,s];
,{t,{-2,-1,0,1,2}}];
,{s,{i,o}}]

Definition of the intermediate pieces (A (OverBar[A]) )

Do[
(*definition of itermediate peices, where one shared edges is counted*)
Do[Bound[A,0,a,s]=Bound[P1,0,a,s],{a,{-2,-1,0,1,2}}];
Bound[A,1,0,s]=Bound[tG3i,s]+(1/(twodgjz[s]))(Bound[ClosedRepLoop,4,s]+2Bound[ClosedRepBubble,4,s]+Bound[ClosedRepTriangle,4,s]);
Bound[A,2,0,s]=Bound[OpenRepBubble,2,s]+Bound[OpenRepTriangle,2,s];

Bound[A,1,1,s]=(1/(twodgjz[s]))(Bound[ClosedRepLoop,4,s]+Bound[ClosedRepBubble,4,s]+Bound[ClosedRepTriangle,4,s]);
Bound[A,1,2,s]=((Bound[ClosedRepTriangle,4,s])/(twodgjz[s]));
Bound[A,2,1,s]=Bound[OpenRepTriangle,2,s];
Bound[A,2,2,s]=Bound[OpenRepSquare,3,s];

Do[
Bound[A,-t1,0,s]=Bound[A,t1,0,s];
,{t1,1,2}];
Clear[t1];

(*definition of itermediate peices, where both shared edges are not counted*)
Do[Bound[Abar,a,0,s]=gj[s]Bound[A,a,0,s],{a,{-2,-1,0,1,2}}]; (*(4.3.25)*)
Do[Bound[Abar,0,a,s]=gj[s]Bound[A,a,0,s],{a,{-2,-1,0,1,2}}]; (*(4.3.26)*)
Bound[Abar,1,1,s]=gj[s](1/(((twodgjz[s]))^2))(Bound[ClosedRepLoop,4,s]+Bound[ClosedRepBubble,4,s]+Bound[ClosedRepTriangle,4,s]);
Bound[Abar,1,2,s]=gj[s]((Bound[OpenRepTriangle,2,s])/(twodgjz[s]));
Bound[Abar,2,1,s]=Bound[Abar,1,2,s];
Bound[Abar,2,2,s]=gj[s]Bound[OpenRepTriangle,1,s];


(*Using Symmetrie we define the other ones*)
Do[Do[
Do[
Bound[t,a,-b,s]=Bound[t,a,b,s];
Bound[t,-a,b,s]=Bound[t,a,b,s];
Bound[t,-a,-b,s]=Bound[t,a,b,s];
,{a,{1,2}}],{b,{1,2}}],{t,{A,Abar}}];
(*the more complex pieces*)
,{s,{i,o}}];

Definition of the Delta entries

Do[
Bound[Delta,start,2,s]=Bound[Delta,I,2,s];
Bound[Delta,start,1,s]=Bound[Delta,I,1,s];
Bound[Delta,start,0,s]=Bound[Delta,I,0,s];
Bound[Delta,start,-1,s]=Bound[Delta,I,1,s];
Bound[Delta,start,-2,s]=Bound[Delta,I,2,s];

Bound[Delta,end,2,s]=Bound[Delta,I,4,s];
Bound[Delta,end,1,s]=Bound[Delta,I,3,s];
Bound[Delta,end,0,s]=Bound[Delta,I,0,s];
Bound[Delta,end,-1,s]=Bound[Delta,I,1,s];
Bound[Delta,end,-2,s]=Bound[Delta,I,2,s];

Bound[Delta,0,0,s]=Bound[Delta,I,0,s];
Bound[Delta,1,0,s]=Bound[Delta,I,3,s]; Bound[Delta,0,-1,s]=Bound[Delta,I,1,s];
Bound[Delta,-1,0,s]=Bound[Delta,I,1,s];  Bound[Delta,0,1,s]=Bound[Delta,I,1,s];
Bound[Delta,-1,1,s]=Bound[Delta,I,5,s]; Bound[Delta,-1,-1,s]=Bound[Delta,I,5,s];
Bound[Delta,1,1,s]=Bound[Delta,I,6,s]; Bound[Delta,1,-1,s]=Bound[Delta,I,6,s];

Do[
Bound[Delta,-2,t,s]=Bound[Delta,I,2,s];
Bound[Delta,2,t,s]=2Bound[Delta,I,2,s];
,{t,-2,2}];
Bound[Delta,-1,2,s]=Bound[Delta,I,2,s];
Bound[Delta,-1,-2,s]=Bound[Delta,I,2,s];
Bound[Delta,1,2,s]=2Bound[Delta,I,2,s];
Bound[Delta,1,-2,s]=2Bound[Delta,I,2,s];
Bound[Delta,0,2,s]=Bound[Delta,I,2,s];
Bound[Delta,0,-2,s]=Bound[Delta,I,2,s];
Do[
Bound[Delta,iotaI,t,s]=Bound[Delta,II,Abs[t],s]+Bound[Delta,I,Abs[t],s]+Bound[tG1i,s]Bound[Delta,0,t,s]+Bound[tG3i,s]Bound[Delta,-1,t,s]+((Bound[ClosedRepBubble,4,s])/(twodgjz[s]))Bound[Delta,-2,t,s];
Bound[Delta,iotaII,t,s]=Bound[Delta,II,Abs[t],s]+Bound[Delta,I,Abs[t],s]+Bound[tG1i,s]Bound[Delta,0,t,s]+2Bound[tG3i,s]Bound[Delta,-1,t,s]+2((Bound[ClosedRepBubble,4,s])/(twodgjz[s]))Bound[Delta,-2,t,s]+2 twodgjz[s]Bound[P1,IotaRib,t,s];
,{t,-2,2}];

,{s,{i,o}}]

Then we defone the pieces for the non-trivial first triangle ((Subscript[(UnderBar[b]), 0])≠ 0) and the entries to bound (Subscript[Ξ, z])(0)-(Subscript[Ξ, z])(k), see (4.4.25)-(4.4.28):

Do[
Bound[hQZero,0,s]=twodgjz[s]Bound[tG3i,s]+Bound[WeightedClosedBubble,2,s];
Bound[hQZero,1,s]=Bound[tG3i,s]+((Bound[WeightedClosedBubble,2,s])/(twodgjz[s]));
Bound[hQZero,2,s]=Bound[WeightedClosedBubble,0,s];
Do[
Bound[DeltaQ,start,t,s]=Bound[Delta,start,t,s]+2(Sum[Bound[Q1,c,s]Bound[Delta,c,-2,s]+Bound[hQZero,c,s]Bound[A,c,t,s],{c,0,2}]);
,{t,-2,2}];
,{s,{i,o}}];

Next we bound (Δ^(iota,I))and (Δ^(iota,II)) as drawn Figure 4.18. The first and third  images  contribution also present for LT. The first bound the second diagram ((Subscript[b, 0])=(v,(Subscript[e, i])) ) with n≠ 0 (step).

AS next we bound (Δ^(iota,I)) and (Δ^(iota,I)) as drawn in Figure 4.18. The first and third diagram are also present for LT and are bounded by Bound[Delta,iotaI or iotaI ,t,s]. The second diagram corresponds to ((Subscript[b, 0])=(v,(Subscript[e, 1])), with v≠ 0. we bound this diagram in Bound[DeltaQ,I/II,step,t,s]. Then be bound the fourth diagam (ribpart1). Then we declare the bounds on forth and sixth diagram (ribpart2)

Do[
Do[
Bound[DeltaQ,II,step,t,s]=Bound[tG2ik,s]Bound[tG3i,s](Bound[Delta,-1,t,s]+2Bound[Delta,-2,t,s])+Bound[tG2ik,s]Bound[OpenRepBubble,4,s]Bound[Delta,-2,t,s];
Bound[DeltaQ,I,step,t,s]=Bound[DeltaQ,II,step,t,s]+ Bound[tG2ik,s]Bound[tG3i,s](Bound[Abar,-1,t,s]+2 Bound[Abar,-2,t,s])+Bound[tG2ik,s]Bound[OpenRepBubble,4,s]Bound[Abar,-2,t,s];
Bound[DeltaQ,I,ribpart1,t,s]=2d Bound[tG1i,s](Bound[Delta,start,-t,s]+2(Sum[Bound[P1,0,-c,s]Bound[Delta,-c,t,s]+Bound[Delta,start,-c,s]Bound[A,-c,t,s],{c,0,2}])); (* u = 0 *)
Bound[DeltaQ,II,ribpart1,t,s]=Bound[DeltaQ,I,ribpart1,t,s]+ 2d Bound[tG1i,s]Sum[Bound[P1,0,-c,s]Bound[A,-c,t,s],{c,0,2}];

Bound[DeltaQ,I,ribpart2,t,s]=2Sum[Bound[Q0,sausage,p1,c,s]Bound[Delta,-c,t,s],{c,0,2}]+2 Bound[WeightedOpenBubble,0,s] Bound[OpenRepTriangle,3,s]Sum[ Bound[A,-c,t,s],{c,0,2}]+2Bound[WeightedClosedTriangle,2,s]Bound[tG1,s]( Bound[A,0,t,s]+Bound[A,2,t,s])+2Bound[WeightedClosedBubble,2,s]Bound[tG1,s]Bound[A,2,t,s]+4Bound[WeightedOpenBubble,0,s]Bound[ClosedRepTriangle,3,s];
Bound[DeltaQ,II,ribpart2,t,s]=Bound[DeltaQ,I,ribpart2,t,s]+Sum[Bound[Q0, sausage,r,s]Bound[A,-r,t,s],{r,0,2}]
,{t,-2,2}];
Do[
Bound[DeltaQ,I,t,s]=Bound[Delta,iotaI,t,s]+Sum[Bound[DeltaQ,I,a,t,s],{a,{step,ribpart1,ribpart2}}];
Bound[DeltaQ,II,t,s]=Bound[Delta,iotaII,t,s]+Sum[Bound[DeltaQ,II,a,t,s],{a,{step,ribpart1,ribpart2}}];
,{t,-2,2}];
,{s,{i,o}}]

Definition of the vectors and matices

We condition on the length of the backone and indentify whether the backbone is on the top or bottom of the diagram.

({{-the backbone in on the bottom,d(u,v)≥2.}, {-the backbone in on the bottom, d(u,v)=1.}, {u=v}, {-the backbone in on the top,d(u,v)=1.}, {-the backbone in on the top, d(u,v)≥2.}})

Do[
VectorP1[normal,s]=Table[Bound[P1,0,r-3,s],{r,1,5}];
VectorP1[iota,s]=Table[Bound[P1,IotaStep,r-3,s]+Bound[P1,IotaRib,r-3,s],{r,1,5}];
VectorQ1[normal,s]=Table[Bound[Q1,r-3,s],{r,1,5}];
VectorQ1[iota,s]=Table[Bound[Q1,iota,r-3,s],{r,1,5}];

(*MatrixA[s]=Table[Max[Bound[A,r-3,t-3,s],Bound[A,t-3,r-3,s]],{t,1,5},{r,1,5}];*)
MatrixA[s]=Table[Bound[A,r-3,t-3,s],{t,1,5},{r,1,5}];
MatrixAbar[s]=Table[Bound[Abar,r-3,t-3,s],{t,1,5},{r,1,5}];
VectorAbar[s]=Table[Bound[Abar,r-3,0,s],{r,1,5}];

VectorDelta[startQ,s]=Table[Bound[DeltaQ,start,r-3,s],{r,1,5}];
VectorDelta[end,s]=Table[Bound[Delta,end,r-3,s],{r,1,5}];
VectorDelta[iotaIQ,s]=Table[Bound[DeltaQ,I,r-3,s],{r,1,5}];
VectorDelta[iotaIIQ,s]=Table[Bound[DeltaQ,II,r-3,s],{r,1,5}];
MatrixDelta[s]=Table[Bound[Delta,r-3,t-3,s],{t,1,5},{r,1,5}];
,{s,{i,o}}]

To compute the geometric sum over matricies we compute a representation of (P^((1))) and (P^((1)ι)) by eigenvalue of the matricies A:

Do[
EigenA[s] = Eigensystem[Transpose[MatrixA[s]]];
InverseProductP[normal,s]=Inverse[Transpose[EigenA[s][[2]]]].VectorP1[normal,s];
InverseProductQ[normal,s]=Inverse[Transpose[EigenA[s][[2]]]].VectorQ1[normal,s];
InverseProductQ[iota,s]=Inverse[Transpose[EigenA[s][[2]]]].VectorQ1[iota,s];
Do[
EigenVectorP[normal,j,s]=EigenA[s][[2,j]]*InverseProductP[normal,s][[j]];
EigenVectorQ[normal,j,s]=EigenA[s][[2,j]]*InverseProductQ[normal,s][[j]];
EigenVectorQ[iota,j,s]=EigenA[s][[2,j]]*InverseProductQ[iota,s][[j]];
EigenValue[j,s]=EigenA[s][[1,j]];
,{j,1,5}]
,{s,{i,o}}]

Bound for k=0

Now we first implement the bound on the absolute values of the coefficients stated in Lemma 4.4.5,4.4.6 and Proposition 4.4.8

Do[
Bound[Xi,normal,0,s]=Bound[ClosedRepBubble,3,s];(*Bound for Ξ, we extract the contribtion of (Subscript[Ξi, z]^((0)))(0)=1, explicitly in the analysis*)
Bound[Xi,iota,0,s]=Bound[ClosedRepBubble,3,s]+rho[s]Bound[tG1,s](1+Bound[ClosedRepBubble,3,s]);


Bound[Xi,normal,1,s]=rho[s]Bound[Q1,0,s];
Bound[Xi,iota,1,s]=((rho[s])/(2d ))Bound[Q1,iota,0,s];
factor[normal]=rho[s];
factor[iota]=((rho[s])/(2d));
Do[
Bound[Xi,t,2,s]=factor[t]VectorQ1[t,s].VectorAbar[s];
Bound[Xi,t,3,s]=factor[t]VectorQ1[t,s].MatrixAbar[s].VectorP1[normal,s];
Bound[Xi,t,EvenTail,s]=Bound[Xi,t,2,s]+Abs[factor[t]Sum[EigenVectorQ[t,j,s].MatrixAbar[s].VectorP1[normal,s]/(1-((EigenValue[j,s])^2))EigenValue[j,s],{j,1,5}]];
Bound[Xi,t,OddTail,s]=Bound[Xi,t,3,s]+Abs[factor[t]Sum[EigenVectorQ[t,j,s].MatrixAbar[s].VectorP1[normal,s]/(1-((EigenValue[j,s])^2))((EigenValue[j,s])^2),{j,1,5}]];
,{t,{normal,iota}}];
Bound[Xi,normal,Even,s]=Bound[Xi,normal,EvenTail,s]; (* recall here that extract the contribtion of (Ξ^((0)))(x)=(Subscript[δ, 0,x]) in the analysis.*)
Bound[Xi,iota,Even,s]=Bound[Xi,iota,0,s]+Bound[Xi,iota,EvenTail,s];

Do[
Bound[Xi,t,Odd,s]=Bound[Xi,t,1,s]+Bound[Xi,t,OddTail,s];
Bound[Xi,t,Absolut,s]=Bound[Xi,t,Odd,s]+Bound[Xi,t,Even,s];
,{t,{normal,iota}}];
,{s,{i,o}}];

Bounds for ((OverHat[Ξ])^((N)))(0)-((OverHat[Ξ])^((N)))(k) for N=0,1,2,3

We now compute the bound as given in  Lemma 4.4.5,4.4.6 and Proposition 4.4.8

Do[
Bound[Xi,normal,0,Delta,0,s]=Bound[WeightedClosedBubble,0,s];
Bound[Xi,iota,0,Delta,0,s]=
(1+(2d-1)Bound[tG1i,s])Bound[WeightedClosedBubble,2,s];

Bound[Xi,iota,0,Delta,ei,s]=Bound[WeightedClosedBubble,2,s]+2 d Bound[tG1i,s]+2(2d Bound[tG1,s]Bound[ClosedRepBubble,3,s]+2d Bound[tG1,s]Bound[WeightedClosedBubble,2,s]) ;

Bound[Xi,iota,1,Delta,0,s]=rho[s]Bound[DeltaQ,I,0,s];
Bound[Xi,iota,1,Delta,ei,s]=rho[s]Bound[DeltaQ,II,0,s];
Bound[Xi,normal,1,Delta,0,s]=rho[s]Bound[DeltaQ,start,0,s];

Bound[Xi,normal,2,Delta,0,s]=2rho[s](VectorQ1[normal,s].VectorDelta[end,s]+VectorDelta[startQ,s].VectorP1[normal,s]);
Bound[Xi,iota,2,Delta,0,s]=2rho[s](VectorQ1[iota,s].VectorDelta[end,s]+VectorDelta[iotaIQ,s].VectorP1[normal,s]);
Bound[Xi,iota,2,Delta,ei,s]=2rho[s](VectorQ1[iota,s].VectorDelta[end,s]+VectorDelta[iotaIIQ,s].VectorP1[normal,s]);

,{s,{i,o}}]

Bound for N=3

Do[
Bound[Xi,normal,3,Delta,0,s]=3rho[s]VectorDelta[startQ,s].MatrixA[s].VectorP1[normal,s]+3rho[s]VectorQ1[normal,s].MatrixA[s].VectorDelta[end,s]+3rho[s] VectorQ1[normal,s].MatrixDelta[s].VectorP1[normal,s];
Bound[Xi,iota,3,Delta,0,s]=3rho[s]VectorDelta[iotaIQ,s].MatrixA[s].VectorP1[normal,s]+3rho[s]VectorQ1[iota,s].MatrixA[s].VectorDelta[end,s]+3 rho[s]VectorQ1[iota,s].MatrixDelta[s].VectorP1[normal,s];
Bound[Xi,iota,3,Delta,ei,s]=3rho[s]VectorDelta[iotaIIQ,s].MatrixA[s].VectorP1[normal,s]+3rho[s]VectorQ1[iota,s].MatrixA[s].VectorDelta[end,s]+3 rho[s]VectorQ1[iota,s].MatrixDelta[s].VectorP1[normal,s];
,{s,{i,o}}]

Bounds for (OverHat[Ξ])(0)-(OverHat[Ξ])(k) for N≥4

Bounds for (OverHat[Ξ])(0)-(OverHat[Ξ])(k) for N>=4

We compute the sum over the bound of Proposition 4.4.8 over even N using the technique of Section 5.3.

Do[
Bound[Xi,normal,EvenTail,Delta,0,s]=Abs[rho[s]2(Sum[VectorDelta[startQ,s].EigenVectorP[normal,j,s]((EigenValue[j,s])^2)((1/(((1-((EigenValue[j,s])^2)))^2))+(1/((1-((EigenValue[j,s])^2))))),{j,1,5}]+ Sum[EigenVectorQ[normal,j,s].VectorDelta[end,s]((EigenValue[j,s])^2)((1/(((1-((EigenValue[j,s])^2)))^2))+(1/((1-((EigenValue[j,s])^2))))),{j,1,5}]+ Sum[(EigenVectorQ[normal,j,s]((EigenValue[j,s])^3))/(((1-((EigenValue[j,s])^2)))^2),{j,1,5}].Sum[((EigenVectorP[normal,j,s])/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}]+ Sum[(EigenVectorQ[normal,j,s]((EigenValue[j,s])^2))/(((1-((EigenValue[j,s])^2)))^2),{j,1,5}].Sum[(EigenVectorP[normal,j,s]EigenValue[j,s])/(((1-((EigenValue[j,s])^2)))^2),{j,1,5}])];
Bound[Xi,iota,EvenTail,Delta,0,s]=
Abs[rho[s]2(Sum[VectorDelta[iotaIQ,s].EigenVectorP[normal,j,s]((EigenValue[j,s])^2)((1/(((1-((EigenValue[j,s])^2)))^2))+(1/((1-((EigenValue[j,s])^2))))),{j,1,5}]+ Sum[EigenVectorQ[iota,j,s].VectorDelta[end,s]((EigenValue[j,s])^2)((1/(((1-((EigenValue[j,s])^2)))^2))+(1/((1-((EigenValue[j,s])^2))))),{j,1,5}]+ Sum[((EigenVectorQ[iota,j,s]((EigenValue[j,s])^3))/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}].Sum[((EigenVectorP[normal,j,s])/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}]+ Sum[((EigenVectorQ[iota,j,s]((EigenValue[j,s])^2))/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}].Sum[(((EigenVectorP[normal,j,s]EigenValue[j,s]))/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}])];
Bound[Xi,iota,EvenTail,Delta,ei,s]=Abs[rho[s]2(Sum[VectorDelta[iotaIIQ,s].EigenVectorP[normal,j,s]((EigenValue[j,s])^2)((1/(((1-((EigenValue[j,s])^2)))^2))+(1/((1-((EigenValue[j,s])^2))))),{j,1,5}]+ Sum[EigenVectorQ[iota,j,s].VectorDelta[end,s]((EigenValue[j,s])^2)((1/(((1-((EigenValue[j,s])^2)))^2))+(1/((1-((EigenValue[j,s])^2))))),{j,1,5}]+ Sum[((EigenVectorQ[iota,j,s]((EigenValue[j,s])^3))/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}].Sum[((EigenVectorP[normal,j,s])/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}]+ Sum[((EigenVectorQ[iota,j,s]((EigenValue[j,s])^2))/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}].Sum[(((EigenVectorP[normal,j,s]EigenValue[j,s]))/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}])];
,{s,{i,o}}];

Now we compute the sum over odd N

Do[
Bound[Xi,normal,OddTail,Delta,0,s]=Abs[rho[s](2Sum[VectorDelta[startQ,s].EigenVectorP[normal,j,s]((EigenValue[j,s])^2)((1/(((1-((EigenValue[j,s])^2)))^2))+(2/((1-((EigenValue[j,s])^2))))),{j,1,5}]+ 2Sum[EigenVectorQ[normal,j,s].VectorDelta[end,s]((EigenValue[j,s])^2)((1/(((1-((EigenValue[j,s])^2)))^2))+(2/((1-((EigenValue[j,s])^2))))),{j,1,5}]+2 Sum[(EigenVectorQ[normal,j,s]((EigenValue[j,s])^3))/(((1-((EigenValue[j,s])^2)))^2),{j,1,5}].Sum[((EigenVectorP[normal,j,s])/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}]- Sum[(EigenVectorQ[normal,j,s]((EigenValue[j,s])^2))/(((1-((EigenValue[j,s])^2)))^2),{j,1,5}].Sum[((EigenVectorP[normal,j,s]EigenValue[j,s])/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}])];
Bound[Xi,iota,OddTail,Delta,0,s]=Abs[rho[s](2Sum[VectorDelta[iotaIQ,s].EigenVectorP[normal,j,s]((EigenValue[j,s])^2)((1/(((1-((EigenValue[j,s])^2)))^2))+(2/((1-((EigenValue[j,s])^2))))),{j,1,5}]+ 2Sum[EigenVectorQ[iota,j,s].VectorDelta[end,s]((EigenValue[j,s])^2)((1/(((1-((EigenValue[j,s])^2)))^2))+(2/((1-((EigenValue[j,s])^2))))),{j,1,5}]+2 Sum[((EigenVectorQ[iota,j,s]((EigenValue[j,s])^3))/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}].Sum[((EigenVectorP[normal,j,s])/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}]- Sum[((EigenVectorQ[iota,j,s]((EigenValue[j,s])^2))/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}].Sum[((EigenVectorP[normal,j,s]EigenValue[j,s])/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}])];

Bound[Xi,iota,OddTail,Delta,ei,s]=Abs[rho[s](2Sum[VectorDelta[iotaIIQ,s].EigenVectorP[normal,j,s]((EigenValue[j,s])^2)((1/(((1-((EigenValue[j,s])^2)))^2))+(2/((1-((EigenValue[j,s])^2))))),{j,1,5}]+ 2Sum[EigenVectorQ[iota,j,s].VectorDelta[end,s]((EigenValue[j,s])^2)((1/(((1-((EigenValue[j,s])^2)))^2))+(2/((1-((EigenValue[j,s])^2))))),{j,1,5}]+2 Sum[((EigenVectorQ[iota,j,s]((EigenValue[j,s])^3))/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}].Sum[((EigenVectorP[normal,j,s])/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}]- Sum[((EigenVectorQ[iota,j,s]((EigenValue[j,s])^2))/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}].Sum[((EigenVectorP[normal,j,s]EigenValue[j,s])/(((1-((EigenValue[j,s])^2)))^2)),{j,1,5}])];
,{s,{i,o}}];

Summation of the Delta Bounds

Do[
Do[
Bound[Xi,t,Even,Delta,0,s]=Bound[Xi,t,0,Delta,0,s]+Bound[Xi,t,2,Delta,0,s]+Bound[Xi,t,EvenTail,Delta,0,s];
Bound[Xi,t,Odd,Delta,0,s]=Bound[Xi,t,1,Delta,0,s]+Bound[Xi,t,3,Delta,0,s]+Bound[Xi,t,EvenTail,Delta,0,s];
Bound[Xi,t,Absolut,Delta,0,s]=Bound[Xi,t,Odd,Delta,0,s]+Bound[Xi,t,Even,Delta,0,s];
,{t,{normal,iota}}];

Bound[Xi,iota,Even,Delta,ei,s]=Bound[Xi,iota,0,Delta,ei,s]+Bound[Xi,iota,2,Delta,ei,s]+Bound[Xi,iota,EvenTail,Delta,ei,s];
Bound[Xi,iota,Odd,Delta,ei,s]=Bound[Xi,iota,1,Delta,ei,s]+Bound[Xi,iota,3,Delta,ei,s]+Bound[Xi,iota,OddTail,Delta,ei,s];
Bound[Xi,iota,Absolut,Delta,ei,s]=Bound[Xi,iota,Odd,Delta,ei,s]+Bound[Xi,iota,Even,Delta,ei,s];
,{s,{i,o}}]

Computation of constants of Proposition 3.3.1

In this section we perform the computations of Section 3.4. to obtain the constances stated in Proposition 3.3.1:

(∑_x)|F(x)|≤  (Subscript[K, F])=Bound[KF]
Bound[KPhi,1]=(Subscript[(UnderBar[K]), Φ])≤(OverHat[Φ])(0)≤  (Subscript[(OverBar[K]), Φ])=Bound[KPhi,2]
Bound[KPhiabs,1]=(Subscript[(UnderBar[K]), |Φ|])≤(∑_x)|Φ(x)|≤  (Subscript[(OverBar[K]), |Φ|])=Bound[KPhiabs,2]
(∑_(x≠0))|(Subscript[Φ, z])(x)|≤  (Subscript[K, |Φ|])=Bound[KPhiWithoutZero]

(∑_x)F(x)[1-cos(k x)]≥ (Subscript[K, Lower])[1-(OverHat[D])(k)]
(∑_x)|F(x)|[1-cos(k x)]≤  (Subscript[K, ΔF])[1-(OverHat[D])(k)]
(∑_x)|(Subscript[Φ, z])(x)|[1-cos(k x)]≤  (Subscript[K, ΔΦ])[1-(OverHat[D])(k)]

Bound on absolute value (Subscript[K, F])and (Subscript[K, Φ])

Do[
alpha[s]=((twodgjz[s])/(2d));
baralpha[s]=((twodgz[s])/(2d));
Bound[KPsi,s]=rho[s]+((2d-2)/(2d))Bound[Xi,normal,Absolut,s];
Bound[KF,s]=(2d baralpha[s])/(1-alpha[s]-(2d-2)alpha[s]Bound[Xi,iota,Absolut,s])Bound[KPsi,s];
Bound[KPhiup,s]=1+Bound[Xi,normal,Even,s]+Bound[Xi,iota,Absolut,s]Bound[KF,s];
Bound[KPhidown,s]=1-Bound[Xi,normal,Odd,s]-Bound[Xi,iota,Absolut,s]Bound[KF,s];
Bound[KPhiabsup,s]=1+Bound[Xi,normal,Absolut,s]+Bound[Xi,iota,Absolut,s]Bound[KF,s];
Bound[KPhiabsdown,s]=1-Bound[Xi,normal,Absolut,s]-Bound[Xi,iota,Absolut,s]Bound[KF,s];
Bound[KPhiWithoutZero,s]=Bound[Xi,normal,Absolut,s]+Bound[Xi,iota,Absolut,s]Bound[KF,s];
,{s,{i,o}}]

Bounds on differences

Next we implement the computation of Section 3.4.3. First the differences of (Subscript[F, 1])and (Subscript[Φ, 1]), lines (3.4.26),  (3.4.27),  (3.4.29)

Bound[DifferencefF,Part1,Lower,i]= ((2d baralpha[i])/(1-((alpha[i])^2)))(1-Bound[tG1i,i]-Bound[Xi,normal,Odd,Delta,0,i]-Bound[Xi,normal,Odd,i]-alpha[i]Bound[Xi,normal,Even,Delta,0,i]);
Bound[DifferencefF,Part1,Absolut,i]=((2d baralpha[i])/(1-((alpha[i])^2)))(rho[i]+(1+alpha[i])Bound[Xi,normal,Absolut,Delta,0,i]+Bound[Xi,normal,Absolut,i]);
Bound[DifferencefF,Part1,Lower,o]=Min[((2d baralpha[i])/(1-((alpha[i])^2))),((2d baralpha[o])/(1-((alpha[o])^2)))](1-Bound[tG1i,o]-Bound[Xi,normal,Odd,Delta,0,o]-Bound[Xi,normal,Odd,o]-alpha[o]Bound[Xi,normal,Even,Delta,0,o]);
Bound[DifferencefF,Part1,Absolut,o]=Max[((2d baralpha[i])/(1-((alpha[i])^2))),((2d baralpha[o])/(1-((alpha[o])^2)))](rho[i]+(1+alpha[o])Bound[Xi,normal,Absolut,Delta,0,o]+Bound[Xi,normal,Absolut,o]);
Do[
Bound[KDeltaPhi,Part1,s]=Bound[Xi,normal,Absolut,Delta,0,s]+((baralpha[s])/(1-((alpha[s])^2)))(2d Bound[Xi,normal,Absolut,Delta,0,s]Bound[Xi,iota,Absolut,s]+(1+Bound[Xi,normal,Absolut,s])Bound[Xi,iota,Absolut,Delta,ei,s]+2d alpha[s]Bound[Xi,normal,Absolut,Delta,0,s]Bound[Xi,iota,Absolut,s]+alpha[s](1+Bound[Xi,normal,Absolut,s])Bound[Xi,iota,Absolut,Delta,0,s]);
,{s,{i,o}}]

Then the differences of (Subscript[F, 2])and (Subscript[Φ, 2]): For the bound in (3.4.30), (3.4.32) and  (3.4.35)

Do[
Bound[DifferencefF,Part2,Lower,s]=
-((((2d baralpha[s]))^2)/(1-((alpha[s])^2)))(Bound[Xi,normal,Odd,Delta,0,s]Bound[Xi,iota,Odd,s]+Bound[Xi,normal,Even,Delta,0,s]Bound[Xi,iota,Even,s])
-((2d ((baralpha[s])^2))/(1-((alpha[s])^2)))(rho[s]+((2d-2)/(2d))Bound[Xi,normal,Even,s])( Bound[Xi,iota,Even,Delta,ei,s]+2d Bound[Xi,iota,Even,s]+ ((alpha[s])^2)Bound[Xi,iota,Even,Delta,0,s]+alpha[s](Bound[Xi,iota,Odd,Delta,ei,s]+Bound[Xi,iota,Odd,Delta,0,s]+2d Bound[Xi,iota,Odd,s]))-((2d ((baralpha[s])^2))/(1-((alpha[s])^2)))(((2d-2)/(2d))Bound[Xi,normal,Odd,s])( Bound[Xi,iota,Odd,Delta,ei,s]+2d Bound[Xi,iota,Odd,s]+ ((alpha[s])^2)Bound[Xi,iota,Odd,Delta,0,s]+alpha[s](Bound[Xi,iota,Even,Delta,ei,s]+Bound[Xi,iota,Even,Delta,0,s]+2d Bound[Xi,iota,Even,s]));
Bound[DifferencefF,Part2,Absolut,s]=((((2d baralpha[s]))^2)/(1-((alpha[s])^2)))Bound[Xi,normal,Absolut,Delta,0,s]Bound[Xi,iota,Absolut,s]
+((2d ((baralpha[s])^2))/((1-((alpha[s])^2))(1+alpha[s])))(rho[s]+((2d-2)/(2d))Bound[Xi,normal,Absolut,s])( Bound[Xi,iota,Absolut,Delta,ei,s]+2d Bound[Xi,iota,Absolut,s]+ alpha[s]Bound[Xi,iota,Absolut,Delta,0,s]);
Bound[KDeltaPhi,Part2,s]=((2d ((baralpha[s])^2))/((1-((alpha[s])^2))))(2d Bound[Xi,normal,Absolut,Delta,0,s] ((Bound[Xi,iota,Absolut,s])^2)+2(1+Bound[Xi,normal,Absolut,s])((Bound[Xi,iota,Absolut,s])/(1+alpha[s]))(Bound[Xi,iota,Absolut,Delta,ei,s]+alpha[s]Bound[Xi,iota,Absolut,Delta,0,s]));
,{s,{i,o}}]

Finally, we compute the differences of (Subscript[F, 3])and (Subscript[Φ, 3]), lines  (4.4.37) and  (4.4.38)

Do[
tmp=(1/(1-((2d alpha[s] Bound[Xi,iota,Absolut,s])/(1-alpha[s]))));
Bound[DifferencefF,Part3,Absolut,s]=Bound[Xi,normal,Absolut,Delta,0,s]((2d baralpha[s])/(((1-alpha[s]))^3))(((2d alpha[s]Bound[Xi,iota,Absolut,s]))^2)tmp+(1+Bound[Xi,normal,Absolut,s])((baralpha[s](((2d alpha[s]))^2))/((((1-alpha[s]))^2)(1-((alpha[s])^2))))Bound[Xi,iota,Absolut,s](tmp^2)(Bound[Xi,iota,Absolut,Delta,ei,s]+alpha[s] Bound[Xi,iota,Absolut,Delta,0,s])+(1+Bound[Xi,normal,Absolut,s])((baralpha[s](((2d alpha[s]))^2))/((((1-alpha[s]))^2)(1-((alpha[s])^2))))Bound[Xi,iota,Absolut,s]tmp(Bound[Xi,iota,Absolut,Delta,ei,s]+alpha[s] Bound[Xi,iota,Absolut,Delta,0,s]+2d Bound[Xi,iota,Absolut,s]);

Bound[DifferencefF,Part3,Lower,s]=-Bound[DifferencefF,Part3,Absolut,s];
Bound[KDeltaPhi,Part3,s]=Bound[Xi,normal,Absolut,Delta,0,s]((2d baralpha[s]Bound[Xi,iota,Absolut,s])/(((1-alpha[s]))^3))(((2d alpha[s]Bound[Xi,iota,Absolut,s]))^2)tmp+(1+Bound[Xi,normal,Absolut,s])(baralpha[s](((2d alpha[s]Bound[Xi,iota,Absolut,s]))^2))/((((1-alpha[s]))^2)(1-((alpha[s])^2)))((tmp^2)+tmp)(1/(1+alpha[s]))(Bound[Xi,iota,Absolut,Delta,ei,s]+alpha[s] Bound[Xi,iota,Absolut,Delta,0,s]);

Bound[KDeltaFLower,s]=1/(Bound[DifferencefF,Part1,Lower,s]+Bound[DifferencefF,Part2,Lower,s]+Bound[DifferencefF,Part3,Lower,s]);
Bound[KDeltaF,s]=Bound[DifferencefF,Part1,Absolut,s]+Bound[DifferencefF,Part2,Absolut,s]+Bound[DifferencefF,Part3,Absolut,s];
Bound[KDeltaPhi,s]=Bound[KDeltaPhi,Part1,s]+Bound[KDeltaPhi,Part2,s]+Bound[KDeltaPhi,Part3,s];
Clear[tmp];
,{s,{i,o}}]

Check of the sufficient condition

Now we can compute whether P(γ,Γ,z) is satisfied, see Definition 3.3.2.

Do[
NoBLEBoundF1[s]=((1+((2d-2)/(2d-1)) Gamma1 Bound[Xi,iota,Even,s])/(rho[s]-((2d-2)/(2d)) Bound[Xi,normal,Odd,s]));
NoBLEBoundF2[s]=((2d-2)/(2d-1))Bound[KPhiabsup,s]Bound[KDeltaFLower,s];
,{s,{i,o}}]

and we compute for (Subscript[f, 3])

Do[
NoBLEBoundF3[Part1,s] =(1/(2c1))Bound[KDeltaFLower,s]Bound[KDeltaPhi,s];
NoBLEBoundF3[Part2,s] =(1/(2c2))Bound[KPhiabsup,s]Bound[KDeltaF,s]((Bound[KDeltaFLower,s])^2);
NoBLEBoundF3[Part3,s]=2(((Bound[KDeltaFLower,s])^2)/c3)√(Bound[KDeltaF,s]Bound[KDeltaPhi,s]Bound[KPhiWithoutZero,s]Bound[KF,s]);
NoBLEBoundF3[Part4,s]=2(((Bound[KDeltaFLower,s])^2)/c4)(2Bound[KPhiabsup,s]((Bound[KDeltaF,s])^2)Bound[KDeltaFLower,s]+√(Bound[KDeltaF,s]Bound[KDeltaPhi,s]Bound[KPhiWithoutZero,s]Bound[KF,s]));
NoBLEBoundF3[s]=Max[NoBLEBoundF3[Part1,s],NoBLEBoundF3[Part2,s],NoBLEBoundF3[Part3,s],NoBLEBoundF3[Part4,s]];
,{s,{i,o}}]

We finally check

Do[
Succes[f1,s]=NoBLEBoundF1[s]<Gamma1;
Succes[f2,s]=NoBLEBoundF2[s]<Gamma2;
Succes[f3,s]=NoBLEBoundF3[s]<Gamma3;
Succes[s]=Succes[f1,s]&&Succes[f2,s]&& Succes[f3,s];
,{s,{i,o}}]
Succes[overall]=Succes[i]&&Succes[o];

Result

The overall result

The statement that the bootstrap was succesful is

Succes[overall]

If this succedes than the analysis of Section 3.3 can be used to proved mean-field behavoior for LT.

Assuming the bootstrap was succesful we prove the following bounds: The infrared bound in (3.3.12) and (3.3.13) hold with

((2d-2)/(2d-1))Gamma2(* ≥ (Subscript[G, z])(k)[1-(OverHat[D])(k)]*)
Max[Bound[KDeltaFLower,o],1](* Nominator in (4.3.13) *)

Further, we have proven that (Subscript[g, (Subscript[z, c])])(Subscript[z, c]) is smaller than

(1/(2d-1))Gamma1

and that (Subscript[g, (Subscript[z, c])]) smaller than

Gamma1*Exp[1]

The improvement of bounds

bubbles={Graphics[{Green,Disk[{0,0},0.8]},ImageSize-> 30],Graphics[{Red,Disk[{0,0},0.8]},ImageSize-> 40]};
tableClassicCheck={{Bounds,Init-(Subscript[f, 1]),Init-(Subscript[f, 2]),Init1-(Subscript[f, 3]),Init2-(Subscript[f, 3]),Init3-(Subscript[f, 3]),Init4-(Subscript[f, 3]),(Subscript[f, 1]),(Subscript[f, 2]),(Subscript[f, 31]),(Subscript[f, 32]),(Subscript[f, 33]),(Subscript[f, 34])},{Gamma,Gamma1,Gamma2,Gamma3 ,Gamma3 ,Gamma3 ,Gamma3 ,Gamma1,Gamma2,Gamma3,Gamma3 ,Gamma3 ,Gamma3  },{Bounds,NoBLEBoundF1[i],NoBLEBoundF2[i],NoBLEBoundF3[Part1,i] ,NoBLEBoundF3[Part2,i] ,NoBLEBoundF3[Part3,i],NoBLEBoundF3[Part4,i] ,NoBLEBoundF1[o],NoBLEBoundF2[o],NoBLEBoundF3[Part1,o] ,NoBLEBoundF3[Part2,o] ,NoBLEBoundF3[Part3,o] ,NoBLEBoundF3[Part4,o] },{ check,
If[NoBLEBoundF1[i]<Gamma1,bubbles[[1]],bubbles[[2]]],If[NoBLEBoundF2[i]<Gamma2,bubbles[[1]],bubbles[[2]]],If[NoBLEBoundF3[Part1,i]<Gamma3,bubbles[[1]],bubbles[[2]]],If[NoBLEBoundF3[Part2,i]<Gamma3,bubbles[[1]],bubbles[[2]]],If[NoBLEBoundF3[Part3,i]<Gamma3,bubbles[[1]],bubbles[[2]]],If[NoBLEBoundF3[Part4,i]<Gamma3,bubbles[[1]],bubbles[[2]]],If[NoBLEBoundF1[o]<Gamma1,bubbles[[1]],bubbles[[2]]],If[NoBLEBoundF2[o]<Gamma2,bubbles[[1]],bubbles[[2]]],If[NoBLEBoundF3[Part1,o]<Gamma3,bubbles[[1]],bubbles[[2]]],If[NoBLEBoundF3[Part2,o]<Gamma3,bubbles[[1]],bubbles[[2]]],If[NoBLEBoundF3[Part3,o]<Gamma3,bubbles[[1]],bubbles[[2]]],If[NoBLEBoundF3[Part4,o]<Gamma3,bubbles[[1]],bubbles[[2]]],},{Required,NoBLEBoundF1[i],NoBLEBoundF2[i],NoBLEBoundF3[Part1,i]/Gamma3 ,NoBLEBoundF3[Part2,i] /Gamma3,NoBLEBoundF3[Part3,i]*c3/Gamma3 ,NoBLEBoundF3[Part4,i]*c4 /Gamma3,NoBLEBoundF1[o],NoBLEBoundF2[o],NoBLEBoundF3[Part1,o]*c1/Gamma3 ,NoBLEBoundF3[Part2,o] *c2/Gamma3,NoBLEBoundF3[Part3,o]*c3/Gamma3,NoBLEBoundF3[Part4,o]*c4/Gamma3}};
Labeled[Grid[tableClassicCheck,Alignment->{Center},Frame->True,Dividers->{{2->True,-1->True},{2->True}},ItemStyle->{1->Bold,1->Bold},Background->{Automatic,Automatic,{{2,2},{2,15}}->GrayLevel[0.7]}],Style["Result for Dimension "Text[d],Bold],Top]//Text

In the following we give a semi-automate proceedure to find appropiate value for the constants (Subscript[Γ, i])and (Subscript[c, i]).

Initially we guess a good value for the constant and make a first computation. Then we deactivate there initial definition at the top of the document and use the code below. We recompile the document a number of times and hope that the algorithm below converges to a fixed point.

(*d=49;
{d,Gamma1,Gamma2,Gamma3,c1,c2,c3,c4}
Gamma1=NoBLGamma1=NoBLEBoundF1[o]+0.000001;
Gamma2=NoBLEBoundF2[o]+0.000001;
c1=NoBLEBoundF3[Part1,o]*c1/Gamma3+0.00001;
c2=NoBLEBoundF3[Part2,o]*c2/Gamma3+0.00001;
c3=NoBLEBoundF3[Part3,o]*c3/Gamma3+0.00001;
c4=NoBLEBoundF3[Part4,o]*c4/Gamma3+0.0001;
{d,Gamma1,Gamma2,Gamma3,c1,c2,c3,c4}*)

{49,1.00789,1.15215,1.2,0.0705639,0.655501,0.187407,7.27392}

Print out of the computed bounds in the coefficients

Do[MethodeFourTable[s]={{Quantity,(Ξ^Zero),(Ξ^One),(Ξ^Two),(Ξ^Three),(Ξ^EvenTail),(Ξ^OddTail)},{Text[Bound for (OverHat[Ξ])],Bound[Xi,normal,0,s],Bound[Xi,normal,1,s] ,Bound[Xi,normal,2,s],Bound[Xi,normal,3,s],Bound[Xi,normal,EvenTail,s],Bound[Xi,normal,OddTail,s]},{Text[Bound for ((OverHat[Ξ])^ι)],Bound[Xi,iota,0,s],Bound[Xi,iota,1,s] ,Bound[Xi,iota,2,s],Bound[Xi,iota,3,s],Bound[Xi,iota,EvenTail,s],Bound[Xi,iota,OddTail,s]},{Text[(OverHat[Ξ])(1-cos(kx))],Bound[Xi,normal,0,Delta,0,s],Bound[Xi,normal,1,Delta,0,s],Bound[Xi,normal,2,Delta,0,s],Bound[Xi,normal,3,Delta,0,s],Bound[Xi,normal,EvenTail,Delta,0,s],Bound[Xi,normal,OddTail,Delta,0,s]},{Text[ (Ξ^ι)(1-cos(kx))],Bound[Xi,iota,0,Delta,0,s],Bound[Xi,iota,1,Delta,0,s],Bound[Xi,iota,2,Delta,0,s],Bound[Xi,iota,3,Delta,0,s],Bound[Xi,iota,EvenTail,Delta,0,s],Bound[Xi,iota,OddTail,Delta,0,s]},{Text[(Ξ^ι)(1-cos(k(x-(Subscript[e, ι]))))] ,Bound[Xi,iota,0,Delta,ei,s],Bound[Xi,iota,1,Delta,ei,s] ,Bound[Xi,iota,2,Delta,ei,s],Bound[Xi,iota,3,Delta,ei,s],Bound[Xi,iota,EvenTail,Delta,ei,s],Bound[Xi,iota,OddTail,Delta,ei,s]}};
,{s,{i,o}}]
MethodeFourTablePart1={{Quantity,KF,KPhi,DELTAFLower,DELTAFAbsolut,DELTAPhi},{Bound for ,Bound[KF,o],Bound[KPhiup,o],Bound[KDeltaFLower,o],Bound[KDeltaF,o],Bound[KDeltaPhi,o]}};
MethodeFourTablePart2={{Quantity,DELTAFLower,2,3,DELTAFAbsolut,2,3,DELTAPhi,2,3},{Bound for ,Bound[DifferencefF,Part1,Lower,o],Bound[DifferencefF,Part2,Lower,o],Bound[DifferencefF,Part3,Lower,o],Bound[DifferencefF,Part1,Absolut,o],Bound[DifferencefF,Part2,Absolut,o],Bound[DifferencefF,Part3,Absolut,o],Bound[KDeltaPhi,Part1,o],Bound[KDeltaPhi,Part2,o],Bound[KDeltaPhi,Part3,o]}};

Labeled[Grid[MethodeFourTable[i],Alignment->{Center},Frame->True,Dividers->{{2->True,-1->True},{2->True}},ItemStyle->{1->Bold,1->Bold},Background->{{None},{GrayLevel[0.9]},{None}}],Style["Bound on coefficients at \!\(\*SubscriptBox[\(z\), \(\(I\)\(\\ \)\)]\)in Dimension "Text[d],Bold],Top]//Text
Labeled[Grid[MethodeFourTable[o],Alignment->{Center},Frame->True,Dividers->{{2->True,-1->True},{2->True}},ItemStyle->{1->Bold,1->Bold},Background->{{None},{GrayLevel[0.9]},{None}}],Style["Bound on coefficients in Dimension "Text[d],Bold],Top]//Text

Labeled[Grid[MethodeFourTablePart1,Alignment->{Center},Frame->True,Dividers->{{2->True,-1->True},{2->True}},ItemStyle->{1->Bold,1->Bold},Background->{{None},{GrayLevel[0.9]},{None}}],Style["Bound on the constants of Proposition 3.3.1 in Dimension "Text[d],Bold],Top]//Text
Labeled[Grid[MethodeFourTablePart2,Alignment->{Center},Frame->True,Dividers->{{2->True,-1->True},{2->True}},ItemStyle->{1->Bold,1->Bold},Background->{{None},{GrayLevel[0.9]},{None}}],Style["Bound on the constants of Proposition 3.3.1 in Dimension "Text[d],Bold],Top]//Text